How to prevent invalid data insert SQL - sql

Question

In my project, I need to check conditions dynamically. To achieve this create table as follows.
CREATE TABLE myconditions
(
conditionid INT IDENTITY PRIMARY KEY CLUSTERED,
minvalue INT,
maxvalue INT,
result INT
)
and there data containing as follows,
insert into MyConditions (MinValue, MaxValue, Result)
values (10, 20, 1), (20, 30, 2), (null, 10, 3), (30, null, 3)
I use this table data to check the range of the age,
declare #age int = 25 --this represents user age
select *
from MyConditions
where #age > isnull(MinValue, #age - 1)
and #age <= isnull(MaxValue, #age)
but now the problem is, suppose if someone inserts an invalid range, such as values (5, 25, 4) i mean this is invalid, because in the database already have (10, 20, 1) this values. when the #age = 15 both condition will be through. so I need to prevent (5, 25, 4) this values addition. if someone needs to add this (5, 25, 4) range, This range values (10, 20, 1) should be deleted.
I insert those data into the database using an ASP.NET MVC application. How can I do this? In my project Is using Oracle. (in this question I used MS SQL sample code, but I need oracle)

Answer 1

This sort of data integrity validation is very difficult to implement in a robust and performative fashion.
For starters, much depends upon the definition of overlapping range. For instance it could be argued that all your sample data ranges are invalid: maxvalue = 10 overlaps with minvalue = 10, assuming bounds are testing with >= and <= which is default. Likewise, null bounds create complexity: if you have an existing range (30, null) is (40,50) valid?
So once you have sorted out your business logic there's the matter of implementing them. In Oracle we can do something with a compound trigger. For each row we store the ID of the inserted / updated row in an array. Then at the end of the statement we loop through the array and query the table in a cross join to compare the date ranges.
create or replace trigger myconditions_trg
for insert or update of minvalue, maxvalue
on myconditions
compound trigger
type condition_array is table of int
index by binary_integer;
conditions condition_array;
procedure validate_range (p_id in int) is
overlapping_range exception;
dummy char(1);
begin
begin
select null into dummy
from myconditions t1
, myconditions t2
where t1.conditionid = p_id
and t2.conditionid != p_id
and t1.minvalue != t2.minvalue
and (
t1.minvalue between t2.minvalue and t2.maxvalue
or
t1.maxvalue between t2.minvalue and t2.maxvalue
)
and rownum = 1;
raise overlapping_range;
exception
when no_data_found then
-- what we're hoping for, no overlaps found
null;
end;
exception
when overlapping_range then
raise_application_error(-20000,
'overlapping range for id #' || p_id);
end validate_range;
procedure validate_ranges is
l_id int;
begin
l_id := conditions.first;
loop
exit when l_id is null;
validate_range (l_id);
l_id := conditions.next(l_id);
end loop;
conditions.delete;
exception
when others then
conditions.delete;
raise;
end validate_ranges;
BEFORE EACH ROW is
begin
-- store id to validate
conditions(:new.conditionid) := 1;
end before each row;
AFTER STATEMENT is
begin
validate_ranges;
end after statement;
end myconditions_trg;
This trigger doesn't attempt to handle multi-user scenarios. To be honest there's not much we can do to prevent two different sessions creating overlapping ranges. The only thing which is guaranteed is to lock the whole table, but that may not be desirable.
If you're interested I have a published a demo on Oracle LiveSQL (free login required, sorry!). Find it here.

Answer 2

You need to use either a trigger or a user-defined function for this.
A simple check constraint can only check the values in a single. Frankly, I think a trigger would be the more common approach.
The exact syntax for either depends on the database -- and you have specified two of them -- so a more detailed answer isn't feasible.