adding decimals to a textbox through a function - vb.net

Question

i have a piece of code that is to be repeated several times throughout my form when certain buttons are pressed. on the clicking of the buttons it should be adding to the decimal value inside the textbox by the value that varies from button to button.my code so far looks like this:
Function EditPrice(ByVal a As Decimal, ByVal b As Decimal)
Dim num1 As Decimal
num1 = a + b
Return num1
End Function
Private Sub btnMinusMushroom_Click(sender As Object, e As EventArgs) Handles btnMinusMushroom.Click
EditPrice(CDec(txtEditCost.Text) + "0.5")
End Sub
if that isn't clear what the code should be doing, the variable of "a" in the function "EditPrice" is the decimal value inside the textbox "txtEditCost" and the decimal value of .5 is the value that should be added to the textbox value.
the function name is underlined red saying "argument not specified for parameter 'b' of 'public function EditPrice(ByVal a As Decimal, ByVal b As Decimal) as object' ".
i dont know what that means or how to fix the problem, any ideas?, thanks

Answer 1

There are a number of issues with your code. To help you avoid such issues in future, I strongly suggest that you set Option Strict On. That will disallow narrowing implicit conversions and late-binding, which will force you to give more consideration to the data types you're using. You can set it On for the current project in the project properties. You can also set it On in the IDE options so that it will be On by default for all future projects.
The first issue is one that Option Strict On would flag, i.e. you have declared a function without a return type. This:
Function EditPrice(ByVal a As Decimal, ByVal b As Decimal)
should be this:
Function EditPrice(ByVal a As Decimal, ByVal b As Decimal) As Decimal
The second issue relates to the naming of that function. You have named it EditPrice but, if you look at the actual code of the method, the name has nothing at all to do with it. There's no price there and there's no editing. All it does is add two numbers of type Decimal and return the result. There's nothing about that that requires the numbers to represent a price and nothing is edited because nothing is changed by the method.
The third issue is with how you're calling the method. The method is declared as taking two Decimal arguments yet what are you doing?
EditPrice(CDec(txtEditCost.Text) + "0.5")
How does that make sense? You get a String from a TextBox and convert that to a Decimal and then you add another String to that and then pass that single result to the method. That's all kinds of wrong. Firstly, why are you adding a String to a Decimal? If you want to add the number 0.5 to something then use a number, not a String. If you want to add to a Deciaml then use a `Decimal number. Secondly, why are you adding the two numbers there and passing the result to the method when the whole point of the method is to add the two numbers? That code should be more like this:
EditPrice(CDec(txtEditCost.Text), 0.5D)
That's still a problem though because, as I said, the EditPrice method doesn't actually edit anything. It just adds two inputs and returns the result, but you don't actually use that result. You presumably want to display that result somewhere. If it's in the same TextBox again then you need to do that:
txtEditCost.Text = EditPrice(CDec(txtEditCost.Text), 0.5D).ToString()
Note the ToString call there too. That will be required by Option Strict On because that Text property is type String and that method returns a Decimal.
The code is still a bit dodgy even with those changes. What's the point of a method that adds two numbers and returns the result when you could do that inline with a simple addition operator? If a method is to be named EditPrice then it actually ought to edit a price. In that case, it would make more sense to have it take a single number to add to the current price and then have the method make the change, e.g.
Private Sub EditPrice(valueToAdd As Decimal)
Dim currentValue As Decimal
'This will get the current value or zero if there is no valid value.
Decimal.TryParse(txtEditCost.Text, currentValue)
Dim newValue As Decimal = currentValue + valueToAdd
txtEditCost.Text = newValue.ToString()
End Sub
Note that that is a Sub rather than a Function because it actually makes a change rather than return a value that other code uses to make a change. In this case, the name actually describes what the method does. Method names should ALWAYS describe what the method actually does.