VBA using cell values instead of cell names - vba

Question

I know that I can select a range when I have cell names. For example Range(A1:B30).select in VBA.
Is there a way to select a range with values written in the cells? I know the following code does NOT work but only that you know what I mean. Range(217:216,9).select.
I want to search for a value and specify the range but how can I do this?
I have already searched the web but I can not find a solution. I also tried to record the macro but it only recorded the code with cell names. I am new to VBA and I can't find a solution for my problem somewhere else. I hope you can understand what I mean.

Answer 1

Say we have:
and we want the range with values between (and including) 10 and 20. This code:
Sub RangeFromValues()
Dim v1 As Long, v2 As Long
Dim r1 As Range, r2 As Range, rng As Range
v1 = 10
v2 = 20
Set r1 = Range("A:A").Find(what:=v1, after:=Range("A1"))
Set r2 = Range("A:A").Find(what:=v2, after:=r1)
Set rng = Range(r1, r2)
rng.Select
End Sub
will produce:

Answer 2

Public Sub TestMe()
Range("1:10").Cells.SpecialCells(xlCellTypeConstants).Select
End Sub
would select only the values, which are not formulas in the first 10 rows:
To select the formulas: type xlCellTypeFormulas instead of xlCellTypeConstants. Just note, that if you do not have anything to Select, it would throw an error.

Answer 3

Another approach, you only need to specify x (low boundary), y (upper boundary) and rngTest (range where you wish to select cells):
Sub Test()
Dim x As Long, y As Long
Dim rngTest As Range
Set rngTest = Range("A1:J20"): x = 5: y = 10
Call RangebyValue(x, y, rngTest)
End Sub
Private Sub RangebyValue(ByVal x As Long, _
ByVal y As Long, _
ByVal rngTest As Range)
Dim vArr(), i As Long, j As Long, rngSelect As Range
vArr = rngTest.Value
For i = LBound(vArr, 1) To UBound(vArr, 1)
For j = LBound(vArr, 2) To UBound(vArr, 2)
If vArr(i, j) >= x And vArr(i, j) <= y Then
If Not rngSelect Is Nothing Then
Set rngSelect = Union(rngSelect, rngTest.Cells(i, j))
Else
Set rngSelect = rngTest.Cells(i, j)
End If
End If
Next j
Next i
rngSelect.Select
End Sub

Answer 4

I think that #Vityata's solution would work well to select all cells that have any value. If you are trying to find a specific value,
Following #Foxfire And Burns And Burns,
I would recommend using a loop through those cells.
For example:
Sub findTheNine()
Dim rng As Range
For Each rng In Range("I7:L11")
If rng.Value = 9 Then
rng.Select
End If
Next rng
End Sub
However, this would only select one of the '9's you wanted to find