How to change 6 digit number into Date String - vb.net

Question

So, I've found this thread, which talks about my issue exactly, however the solution doesn't work for me: How to Change Format column in Datagridview to date type for this value
I've got a different number patter, in which my data is: YYMMDD, just 6 numerical digits (000901 - September 1st, 2000)
Does the data structure make a difference when converting it to a data string? Does it need to be in an initial format?
This is my current string of code:
DataGridView1.Columns(1).DefaultCellStyle.Format = "yy/MM/dd"
Just trying to get any format what-so-ever, but it just remains as 6 digits.

Answer 1

OK, try this. Set your format in the datagridview to the date format you want to use. For my example, I had 3 columns and the far right column contained the 6 digit strings.
In my 3rd column I set a format of yyyy/MM/dd in the datagridview.
In the button click I looped through the dgv and parsed the values to a datetime which allowed the format to work as it was now working with a date type.
For Each r As DataGridViewRow In DataGridView1.Rows
If Not r.IsNewRow Then
r.Cells(2).Value = DateTime.ParseExact(r.Cells(2).Value.ToString, "yyMMdd", CultureInfo.InvariantCulture)
End If
Next
Upon clicking the button, I got the following results.
Now that the column is a date datatype, we can just change the format and the columns format to the new format setting.
I added a second button and in that button I placed the code
DataGridView1.Columns(2).DefaultCellStyle.Format = "MMM dd, yyyy"
which immediately change the 3rd column to the new format

Answer 2

After some thought and experimentation, I realised how to do this on the GUI instead of when loading the data.
You can achieve this particular formatting by handling the CellFormatting event of the DataGridView.
Test Data I used:
Private Property MyData As DataTable
Private Sub InitialiseData()
MyData = New DataTable
MyData.Columns.Add("YMDString", GetType(String))
Dim dr As DataRow
dr = MyData.NewRow()
dr(0) = "000901"
MyData.Rows.Add(dr)
dr = MyData.NewRow()
dr(0) = "010901"
MyData.Rows.Add(dr)
dr = MyData.NewRow()
dr(0) = "020901"
MyData.Rows.Add(dr)
End Sub
DataGridView configuration
Private Sub SetupDataGridView()
InitialiseData()
DataGridView1.AutoGenerateColumns = False
DataGridView1.Columns.Add("YMDString", "YMD String")
DataGridView1.Columns.Add("YMDDateTime", "YMD DateTime")
DataGridView1.Columns(0).DataPropertyName = "YMDString"
DataGridView1.Columns(1).DataPropertyName = "YMDString"
DataGridView1.DataSource = MyData
AddHandler DataGridView1.CellFormatting, AddressOf DataGridView1OnCellFormatting
End Sub
And the CellFormatting event handler that does the hard work. The DateTime parsing isn't the best you can use, but it does illustrate the principal of what you want to achieve.
Private Sub DataGridView1OnCellFormatting(sender As Object, e As DataGridViewCellFormattingEventArgs)
Dim thisGrid As DataGridView = CType(sender, DataGridView)
If (thisGrid IsNot Nothing AndAlso e.Value IsNot Nothing) Then
If (thisGrid.Columns(e.ColumnIndex).Name = "YMDDateTime") Then
Dim stringValue As String = e.Value.ToString()
Dim year As Integer = 2000 + stringValue.Substring(0, 2)
Dim month As Integer = stringValue.Substring(2, 2)
Dim day As Integer = stringValue.Substring(4, 2)
Dim dt As New DateTime(year, month, day)
e.Value = dt.ToString("yyyy/MM/dd")
End If
End If
End Sub
When run, I get this result:

Answer 3

I took your six digit string and converted to a DateTime then formatted as you wished.
Dim strDate As String = "180211"
Dim myDate As New DateTime(CInt("20" & strDate.Substring(0, 2)), CInt(strDate.Substring(2, 2)), CInt(strDate.Substring(4)))
Debug.Print(myDate.ToString("yy/MM/dd"))
EDIT:
I found a better answer thanks to user1751825 at VB.NET compare date time from string format
Dim myDate As Date = DateTime.ParseExact(strDate, "yyMMdd", CultureInfo.InvariantCulture)