creating user defined form controls in excel vba - vba

Question

i have an excel user form with a comboBox for imputing no of pumps and the combo box contains drop down list from 1 to 30. how can i achieve creation of new form controls depending on the users selection? for instance if the user selects 5 i want to create 5 labels named pump1, pump2 to pump5 all with radio buttons for product selection.

Answer 1

You can do this in a number of ways, the simplest being to, add in all 30 buttons and hide\unhide them with Private Sub ComboBox1_Change() subroutine. If that does not meet your needs, then will you probably want to use the Microsoft Visual Basic for Applications Extensibility 5.3 reference, to add in buttons at runtime, then modify them on the same event.
Example UserForm Code
'' Corresponding UserForm has *only* a combobox called `ComboBox1` located at left=6, top=6.
'' Form-level constants
Private Const maxNumBtns As Integer = 12
Private Const defaultComBoxNum As Integer = 5
'' Update buttons
Private Sub ComboBox1_Change()
Dim comp As Boolean
'' prevent flashing
Let Application.ScreenUpdating = False
For i = 1 To maxNumBtns
With Me.Controls.Item(getBtnName(i))
Let comp = i <= CInt(Me.ComboBox1.Value)
'' ensure hidden buttons are not pressed
Let .Value = comp And .Value
Let .Enabled = comp
Let .Visible = comp
End With
Next
Let Application.ScreenUpdating = True
End Sub
'' Set up UserForm
Private Sub UserForm_Initialize()
Dim i As Integer, _
btn As String
For i = 1 To maxNumBtns
'' add line to combobox
Call Me.ComboBox1.AddItem(i)
Let btn = getBtnName(i)
'' add button
Call Me.Controls.Add( _
bstrProgID:="Forms.OptionButton.1", _
Name:=btn, _
Visible:=True)
'' Format the button
With Me.Controls(btn)
Let .Left = 12
Let .Top = 30 + 17 * i
Let .Width = 70
Let .Height = 15
Let .Caption = "Pump #" & i
End With
Next i
'note: this calls combobox1_change
Let Me.ComboBox1.Value = defaultComBoxNum
End Sub
'' helper function to ensure naming stays the same
Private Function getBtnName(ByVal index As Integer) As String
Let getBtnName = " opBtn" & index
End Function
If you are looking to have something like a combobox with a check box option, you should use a listbox. (you will not need the extensibility reference for this version)
Unfortunately, however, it is not possible to hide a listbox row, so this option requires removing all entries in the listbox when the combobox val is changed.
The methods below correspond to a useform, useform1, with a comboBox, pumpComboBox, a listBox, pumpListBox, and two commandButtons, OkButton and CancelButton.
Option Explicit
'' Calling code
'
'With New Userform1
' .Show
' If Not .IsCancelled Then
' '...
' End If
'End With
Private Const maxChecks As Integer = 12
Private Const defaultChecks As Integer = 5
Private checked() As Boolean
Private cancelled As Boolean
Private updating As Boolean
Private Sub UserForm_Initialize()
Dim i As Integer
ReDim checked(0 To maxChecks - 1) As Boolean
'' Add item to combobox
For i = 1 To maxChecks Step 1
Call Me.pumpComboBox.AddItem(i)
Let checked(i - 1) = False
Next i
'' format listbox
With Me.pumpListBox
Let .ListStyle = fmListStyleOption
Let .MultiSelect = fmMultiSelectMulti
End With
'note: this calls pumpComboBox_change
Let Me.pumpComboBox.value = defaultChecks
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = VbQueryClose.vbFormControlMenu Then
Let cancelled = True
Call OnCancel
End If
End Sub
Private Sub pumpComboBox_Change()
Dim i As Integer
'' prevent flashing
Let Application.ScreenUpdating = False
'' make sure values are not cleared when changing number of options
Let updating = True
Call Me.pumpListBox.Clear
For i = 1 To Me.pumpComboBox.value
Call Me.pumpListBox.AddItem("Pump #" & i)
Let Me.pumpListBox.Selected(i - 1) = checked(i - 1)
Next i
Let updating = False
Let Application.ScreenUpdating = True
End Sub
Private Sub pumpListBox_Change()
If updating Then Exit Sub
Dim i As Integer
For i = 0 To maxChecks - 1
If i < UBound(Me.pumpListBox.List) Then
Let checked(i) = Me.pumpListBox.Selected(i)
Else
'' remove options when reducing number of options
Let checked(i) = False
End If
Next i
End Sub
Public Property Get IsCancelled() As Boolean
Let IsCancelled = cancelled
End Property
Private Sub OkButton_Click()
Call Hide
End Sub
Private Sub CancelButton_Click()
Call OnCancel
End Sub
Private Sub OnCancel()
Let cancelled = True
Call Hide
End Sub