Insert into join table values per each of main table - sql

Question

I have a table called StoreTbl to store the Stores/Markets and this table has a Boolean field called AvailableToAllCities
and there is another Table called CityTbl
And There is a join Table between them called StoreCityJoinTbl
The manager asked me to remove the field AvailableToAllCities (or not use it anymore); So I need to insert to the join table all cities for each Store,
Can I do this without use for-loop?

Answer 1

Without any kind of DDL, I've had to create my own, and used very limited data. This should, however, be enough to get you there:
USE Sandbox;
GO
--Sample data set up
CREATE TABLE Store (StoreID int IDENTITY(1,1), StoreName varchar(50), AvailableToAllCities bit)
CREATE TABLE City (CityID int IDENTITY(1,1), CityName varchar(50));
CREATE TABLE CityStores (ID int IDENTITY(1,1), StoreID int, CityID int)
GO
INSERT INTO City (CityName)
VALUES ('London'),('New York'),('Syndey'),('Washington'),('Paris'),('Berlin'),('Shanghai'),('Tokyo');
INSERT INTO Store (StoreName, AvailableToAllCities)
VALUES ('sdgfkljasghdbfkl',1),
('dsfjklgh',0),
('sdlafiugasdljkbfh',1),
('asdfhjklgasdfjkl',1),
('sdjlhfbvgajldavfhkl',0);
INSERT INTO CityStores (StoreID, CityID)
VALUES (2,1),(2,3),(2,6),
(5,1),(5,2),(5,7),(5,8);
GO
--So your current data looks like this
SELECT S.StoreName, C.CityName
FROM Store S
LEFT JOIN CityStores CS ON S.StoreID = CS.StoreID
JOIN City C ON CS.CityID = C.CityID
OR S.AvailableToAllCities = 1;
GO
--And now the the solution
INSERT INTO CityStores (StoreID,CityID)
SELECT S.StoreID, C.CityID
FROM Store S
CROSS JOIN City C
WHERE S.AvailableToAllCities = 1;
GO
--Drop the old column
ALTER TABLE Store DROP COLUMN AvailableToAllCities;
GO
--And now the new query:
SELECT S.StoreName, C.CityName
FROM Store S
JOIN CityStores CS ON S.StoreID = CS.StoreID
JOIN City C ON CS.CityID = C.CityID;
GO
--Clean up
DROP TABLE Store;
DROP TABLE City;
DROP TABLE CityStores;