Referencing Control Objects Created in Different Module - vba

Question

dr (no circumstantial details): I am trying to reference a control created programmatically in another module, but it is throwing
"Compile Error: Variable not defined."
Here's what I'm trying to do (and perhaps my approach is wrong entirely, if so, let me know): I am trying to create a userform that uses a listbox to act as a menu in which the user can select an item and see the controls (labels, textboxes) relevant to that item. For instance: item "General Information" would a submitter name, department, date, etc; item "Report request" would have report application, desired app name, etc. Selecting "General Information" on the listbox should .visible=true the frame housing the "GI" controls and hide other frames, and selecting "Report Request" item would .visible=false General Information frame but .visible=true Report Request frame, and so on.
Because I want the controls to be placed in the same place on the userform, I created them all programmatically in a Construct module. It looks like this:
Public Sub GeneralInformationCreator()
Dim i As Integer
Dim labelGeneral As MSForms.Label
Dim frameGeneral As MSForms.Frame
Dim frameRequestInformation As MSForms.Frame
Dim frameSubmitterInformation As MSForms.Frame
Dim labelAppSelect As MSForms.Label
Dim listAppSelect As MSForms.ListBox
Dim labelDateSelect As MSForms.Label
Dim comboMonthSelect, comboDaySelect, comboYearSelect As MSForms.ComboBox
Dim labelSubmitterFName, labelSubmitterLName As MSForms.Label
Dim inputSubmitterFName, inputSubmitterLName As MSForms.TextBox
Dim labelSponsorFName, labelSponsorLName As MSForms.Label
Dim inputSponsorFName, inputSponsorLName As MSForms.TextBox
Dim labelDepartmentName As MSForms.Label
Dim inputDepartmentName As MSForms.TextBox
Set labelGeneral = formRequestWizard.Controls.Add("Forms.Label.1", "labelGeneral", True)
With labelGeneral
.Font.Size = 12
.Top = 12
.Left = 192
.Height = 14.25
.Width = 42
.Caption = "General Information"
.Name = labelGeneral
End With
Set frameGeneral = formRequestWizard.Controls.Add("Forms.Frame.1", "frameGeneral", True)
With frameGeneral
.Top = 30
.Left = 192
.Height = 310
.Width = 384
.Caption = ""
.BorderColor = RGB(255, 255, 255)
Set frameRequestInformation = frameGeneral.Controls.Add("Forms.Frame.1", "frameRequestInformation", True)
With frameRequestInformation
.Top = 15
.Left = 15
.Height = 100
.Width = 350
.Caption = "Request Information"
.BorderStyle = 1
.BorderColor = RGB(0, 0, 0)
Set labelAppSelect = frameRequestInformation.Controls.Add("Forms.Label.1", "labelAppSelect", True)
With labelAppSelect
.Caption = "Select an application:"
.Top = 15
.Left = 15
.Width = 100
.Height = 20
.AutoSize = True
End With
The Construct methods are called at runtime using UserForm_Initialize() like this:
Private Sub UserForm_Initialize()
Call Construct.GeneralInformationCreator
Call Construct.ApplicationDetailsCreator
With formRequestWizard.listMenu
.AddItem ("General Information")
.AddItem ("Application Details")
'.Selected(0) = True
End With
End Sub
Here's the issue: in the userform code, I have a listMenu_Change() that looks like this:
Private Sub listMenu_Change()
If (listMenu.Selected(0) = True) Then
labelGeneral.Visible = True
frameGeneral.Visible = True
Else
labelGeneral.Visible = False
frameGeneral.Visible = False
End If
If (listMenu.Selected(1) = True) Then
labelAppDetails.Visible = True
frameAppDetails.Visible = True
Else
labelAppDetails.Visible = False
frameAppDetails.Visible = False
End If
End Sub
Selecting an item from the listbox throws the error from the tl;dr: "Compile Error: Variable not defined" on the first variable "labelGeneral".
I have tried putting all of the script into the userform code window, and putting the control Dims outside of Subs. The research I've done has mostly led to discussions about how to create event handlers for controls created at runtime, but I've decided to place the listMenu object via the object view so I'm not sure that's applicable.

Answer 1

GeneralInformationCreator should be a class in its own right - even the name says so (it's a name like a class/type that is something, not a verb like a procedure that does something).
See all these declarations you have at procedure scope, live and die at procedure scope - they're local variables that nobody else can see:
Dim labelGeneral As MSForms.Label
Dim frameGeneral As MSForms.Frame
Dim frameRequestInformation As MSForms.Frame
Dim frameSubmitterInformation As MSForms.Frame
Dim labelAppSelect As MSForms.Label
Dim listAppSelect As MSForms.ListBox
Dim labelDateSelect As MSForms.Label
Dim comboMonthSelect [As Variant], comboDaySelect [As Variant], comboYearSelect As MSForms.ComboBox
Dim labelSubmitterFName [As Variant], labelSubmitterLName As MSForms.Label
Dim inputSubmitterFName [As Variant], inputSubmitterLName As MSForms.TextBox
Dim labelSponsorFName [As Variant], labelSponsorLName As MSForms.Label
Dim inputSponsorFName [As Variant], inputSponsorLName As MSForms.TextBox
Dim labelDepartmentName As MSForms.Label
Dim inputDepartmentName As MSForms.TextBox
By moving them up to instance level fields (i.e. module-scope variables) in a class module, you can expose a Public Property Get accessor that makes anyone with an instance of that class able to access these objects.
So instead of this:
Private Sub UserForm_Initialize()
Call Construct.GeneralInformationCreator
Call Construct.ApplicationDetailsCreator
With formRequestWizard.listMenu
.AddItem ("General Information")
.AddItem ("Application Details")
'.Selected(0) = True
End With
End Sub
You will have that:
Private generalInfoControls As New GeneralInformationCreator
Private appDetailsControls As New ApplicationDetailsCreator
Private Sub UserForm_Initialize()
generalInfoControls.Create Me.Controls
appDetailsControls.Create Me.Controls
With Me.listMenu 'don't refer to the default instance in the form's code-behind... EVER!
.AddItem "General Information"
.AddItem "Application Details"
'.Selected(0) = True
End With
End Sub
Where Create is a procedure that takes a Controls parameter - by giving it Me.Controls we are passing the collection of controls for the current instance of the user form, so the method can look like this:
Public Sub Create(ByVal parent As Controls)
Set labelGeneral = parent.Add("Forms.Label.1", "labelGeneral", True)
With labelGeneral
.Font.Size = 12
.Top = 12
.Left = 192
.Height = 14.25
.Width = 42
.Caption = "General Information"
.Name = labelGeneral
End With
'...
Notice it's no longer coupled with the default instance of your formRequestWizard form, and will work with whatever form instance's Controls collection it's given.
I'm not sure if you're still following my train of thought here, but this means your handler can now do this:
Private Sub listMenu_Change()
generalInfoControls.SetVisibility listMenu.Selected(0)
appDetailsControls.SetVisibility listMenu.Selected(1)
End Sub
That implies that your XxxxCreator classes have a SetVisibility method that looks something like this:
Public Sub SetVisibility(ByVal isVisible As Boolean)
labelGeneral.Visible = isVisible
frameGeneral.Visible = isVisible
'...

Answer 2

Define all your variables like this:
Dim comboMonthSelect As MSForms.Combobox
Dim comboDaySelect As MSForms.Combobox
Dim comboYearSelect As MSForms.ComboBox
With
Dim comboMonthSelect, comboDaySelect, comboYearSelect As MSForms.ComboBox,
only comboYearSelect is declared as a MSForms.ComboBox and the other two as Variant.
Then write Option Explicit and make sure that every variable is defined in every Sub/Function. In your case is should be:
Dim labelGeneral As MSForms.Label
in the Sub listMenu_Change, where the error is happening. MSDN Option Explicit reference.
As a quick and dirty way, you can do something like this:
If (listMenu.Selected(0) = True) Then
Controls("labelGeneral").Visible = True
Controls("someOtherName").Visible = True
End If
However, this breaks completely any MVC pattern and may cause any non-VBA people to feel dizzy and to publish things like this:
If you want to do it the "correct way", read this article form the ex-StackOverflow Documentation, it is quite nice:
http://www.riptutorial.com/vba/example/19036/best-practices.