Inserting a table of contents on page 2 - vba

Question

I need to create a table of contents that exists at the top of page 2. In my code, I am importing a custom Title page (a building block) and also have to create the Table of Contents based on text in the document. The table of contents works/runs perfectly, it's just in the wrong location.
Sub TitlePage()
Application.Templates( _
mypath). _
BuildingBlockEntries("BuildingBlockName").Insert Where:=Selection.Range, RichText:=True
End Sub
Sub ToC()
Selection.GoTo what:=wdGoToLine, Which:=wdGoToAbsolute
Selection.EscapeKey
Selection.Range.InsertBreak
Selection.GoTo what:=wdGoToPage, Which:=wdGoToNext
Selection.EscapeKey
ActiveDocument.TablesOfContents.Add Range:=Selection.Range, RightAlignPageNumbers:= _
True, UseHeadingStyles:=True, IncludePageNumbers:=True, _
UseHyperlinks:=True, HidePageNumbersInWeb _
:=True, UseOutlineLevels:=False
End Sub
As you can see, these are two different macros that are part of a larger macro. I am using a call function in the main portion of the code to keep things organized. Is there a way to finagle the Table of contents onto page 2?
P.S. I know I've committed the sin of using the selection property. This was to navigate to the first line, then to the second page, then to escape the selection, and insert the ToC where the cursor was last.
I'm desperate.

Answer 1

How about something based on:
Sub ToCAndTitle()
With ActiveDocument
'Insert a Section break before existing content
.Range(0, 0).InsertBreak Type:=wdSectionBreakNextPage
.TablesOfContents.Add Range:=.Range(0, 0), RightAlignPageNumbers:=True, _
UseHeadingStyles:=True, IncludePageNumbers:=True, UseHyperlinks:=True, _
HidePageNumbersInWeb:=True, UseOutlineLevels:=False
'Insert a page break before existing content
.Range(0, 0).InsertBreak Type:=wdPageBreak
Application.Templates(mypath).BuildingBlockEntries("BuildingBlockName").Insert Where:=.Range(0, 0), RichText:=True
End With
End Sub
Inserting a Section break allows the page numbering to start after the TOC, if that's what you want.