Find total debit value for each unique vendor - abap

Question

My internal table looks like this:
Id vendor doc_no debit credit
Abc. Ven1. 123. 4000. 5000
Abc. Ven2. 345. 5000 6000
Abc. Ven1. 367. 8000. 9000
Abc. Ven2. 890. 3000. 8000
Now, I need to find the largest debit for each vendor. On the basis of above example, for vendor Ven1. largest debit will be (4000+8000) = 12000. Similarly for Ven2. vendor the largest debit value will be (5000+3000) = 8000.
How to achieve this??

Answer 1

Here is an example report containing the most performant solution I can think of. It's using the fairly new ABAP commands FOR GROUPS … IN and REDUCE. Just copy it in your system and give it a try.
REPORT Z_SUM_BY_VENDOR.
"Prepare test data
TYPES: BEGIN OF lty_st_data_source,
id TYPE C LENGTH 3,
vendor TYPE C LENGTH 4,
doc_no TYPE C LENGTH 3,
debit TYPE I,
credit TYPE I,
END OF lty_st_data_source.
DATA: lt_data_source TYPE STANDARD TABLE OF lty_st_data_source.
APPEND VALUE #( id = 'Abc' vendor = 'Ven1' doc_no = '123' debit = 4000 credit = 5000 ) TO lt_data_source.
APPEND VALUE #( id = 'Abc' vendor = 'Ven2' doc_no = '345' debit = 5000 credit = 6000 ) TO lt_data_source.
APPEND VALUE #( id = 'Abc' vendor = 'Ven1' doc_no = '367' debit = 8000 credit = 9000 ) TO lt_data_source.
APPEND VALUE #( id = 'Abc' vendor = 'Ven2' doc_no = '890' debit = 3000 credit = 8000 ) TO lt_data_source.
" Define type for sum table and generate sum (actual answer to the question)
TYPES: BEGIN OF lty_st_grouped,
vendor TYPE C LENGTH 4,
debit_sum TYPE I,
END OF lty_st_grouped,
lty_tt_grouped TYPE HASHED TABLE OF lty_st_grouped WITH UNIQUE KEY vendor.
DATA(lt_grouped) = VALUE lty_tt_grouped(
FOR GROUPS vendor_group OF <ls_data_source> IN lt_data_Source
GROUP BY <ls_data_source>-vendor
( VALUE lty_st_grouped( vendor = vendor_group
debit_sum = REDUCE i( INIT sum = 0
FOR <ls_data_source_2> IN GROUP vendor_group
NEXT sum = sum + <ls_data_source_2>-debit )
)
)
).
" Show result for demo purpose
LOOP AT lt_grouped ASSIGNING FIELD-SYMBOL(<ls_grouped>).
WRITE: `Vendor: ` && <ls_grouped>-vendor && ` | Debit Sum: ` && <ls_grouped>-debit_sum.
NEW-LINE.
ENDLOOP.

Answer 2

Create a structure with your required fields in the correct order of dimension(s) and measures. Then you can savely use the "AT" functions, aggregating your debit for each "group of" vendors.
DATA: Begin of ls_itab_ordered
vendor type vendor,
debit type debit,
End of ls_itab_ordered,
lt_itab_ordered like standard table of ls_itab_ordered,
lt_itab_agg like itab.
move-corresponding itab to lt_itab_ordered
sort lt_itab_ordered by vendor.
loop at lt_itab_ordered assigning <ls_itab_ordered>.
at new vendor.
ls_itab_agg-vendor = <ls_itab_ordered>-vendor.
endat.
add <ls_itab_ordered>-debit to ls_itab_agg-debit.
at end of vendor.
append ls_itab_agg to lt_itab_agg.
clear ls_itab_agg.
endat.
endloop.

Answer 3

You can use Collect -
I'm considering it_vendor is your internal table and declare ls_vendor like it_vendor.
TYPES: BEGIN OF ty_calc,
vendor TYPE vendor, " (check DE of vendor then use that)
debit TYPE int4,
END OF ty_calc.
DATA: ls_calc TYPE ty_calc,
lt_calc TYPE TABLE OF ty_calc.
LOOP AT it_vendor INTO ls_vendor.
ls_calc-vendor = ls_vendor-vendor.
ls_calc-debit = ls_vendor-debit.
COLLECT ls_calc INTO lt_calc.
CLEAR : ls_calc , ls_vendor.
ENDLOOP.
Internal table lt_calc holds the largest debit for each vendor.