I have developed a procedure that adds a consultant to a table.
I would like to add a procedure to the consultant ID so that everytime a consultant gets added to the table a generic id is added to the record.
How can I create this procedure?
create or replace PROCEDURE ADD_CONSULTANT
( p_con_id LDS_CONSULTANT.CONSULTANT_ID%type,
p_con_name LDS_CONSULTANT.CST_NAME%type,
p_con_start LDS_CONSULTANT.START_DATE%type,
p_con_end LDS_CONSULTANT.LEAVE_DATE%type,
p_con_loc LDS_CONSULTANT.LOCATION%type,
p_con_spec LDS_CONSULTANT.SPECIALIST_AREA%type)
IS
BEGIN
INSERT INTO LDS_CONSULTANT (CONSULTANT_ID, CST_NAME, START_DATE, LEAVE_DATE, LOCATION, SPECIALIST_AREA)
VALUES (p_con_id, p_con_name, p_con_start, p_con_end, p_con_loc, p_con_spec);
END;
You didn't mention which database version you use, so the answer & the solution you choose might differ.
A simple solution is to use a sequence. Here's an example. First, a table:
SQL> CREATE TABLE lds_consultant (
2 consultant_id NUMBER,
3 cst_name VARCHAR2(20),
4 start_date DATE,
5 leave_date DATE,
6 location VARCHAR2(20),
7 specialist_area VARCHAR2(20)
8 );
Table created.
A sequence:
SQL> CREATE SEQUENCE seq_cons;
Sequence created.
A procedure; I removed parameter which you originally used, as you don't need it any more.
SQL> CREATE OR REPLACE PROCEDURE add_consultant (
2 p_con_name lds_consultant.cst_name%TYPE,
3 p_con_start lds_consultant.start_date%TYPE,
4 p_con_end lds_consultant.leave_date%TYPE,
5 p_con_loc lds_consultant.location%TYPE,
6 p_con_spec lds_consultant.specialist_area%TYPE
7 )
8 IS
9 BEGIN
10 INSERT INTO lds_consultant (
11 consultant_id,
12 cst_name,
13 start_date,
14 leave_date,
15 location,
16 specialist_area
17 ) VALUES (
18 seq_cons.NEXTVAL, --> this
19 p_con_name,
20 p_con_start,
21 p_con_end,
22 p_con_loc,
23 p_con_spec
24 );
25 END;
26 /
Procedure created.
Let's test it:
SQL> BEGIN
2 add_consultant('Littlefoot',trunc(SYSDATE),NULL,'Croatia','IT');
3 END;
4 /
PL/SQL procedure successfully completed.
SQL> SELECT * FROM lds_consultant;
CONSULTANT_ID CST_NAME START_DATE LEAVE_DATE LOCATION SPECIALIST_AREA
------------- -------------------- ---------- ---------- -------------------- --------------------
1 Littlefoot 13.05.2018 Croatia IT
SQL>
Another option is a database trigger:
SQL> CREATE OR REPLACE TRIGGER trg_bi_cons BEFORE
2 INSERT ON lds_consultant
3 FOR EACH ROW
4 BEGIN
5 :new.consultant_id := seq_cons.nextval;
6 END;
7 /
Trigger created.
Unlike the previous example, you don't even need to reference the consultant_id any more as trigger does that job.
SQL> CREATE OR REPLACE PROCEDURE add_consultant (
2 p_con_name lds_consultant.cst_name%TYPE,
3 p_con_start lds_consultant.start_date%TYPE,
4 p_con_end lds_consultant.leave_date%TYPE,
5 p_con_loc lds_consultant.location%TYPE,
6 p_con_spec lds_consultant.specialist_area%TYPE
7 )
8 IS
9 BEGIN
10 INSERT INTO lds_consultant (
11 cst_name,
12 start_date,
13 leave_date,
14 location,
15 specialist_area
16 ) VALUES (
17 p_con_name,
18 p_con_start,
19 p_con_end,
20 p_con_loc,
21 p_con_spec
22 );
23
24 END;
25 /
Procedure created.
Testing:
SQL> BEGIN
2 add_consultant('Bigfoot',trunc(SYSDATE),NULL,'France','Fashion');
3 END;
4 /
PL/SQL procedure successfully completed.
SQL> SELECT * FROM lds_consultant;
CONSULTANT_ID CST_NAME START_DATE LEAVE_DATE LOCATION SPECIALIST_AREA
------------- -------------------- ---------- ---------- -------------------- --------------------
1 Littlefoot 13.05.2018 Croatia IT
2 Bigfoot 13.05.2018 France Fashion
SQL>
If you're on 12c database version, use the identity column:
CREATE TABLE lds_consultant (
consultant_id NUMBER GENERATED BY DEFAULT ON NULL AS IDENTITY,,
cst_name VARCHAR2(20),
start_date DATE,
leave_date DATE,
location VARCHAR2(20),
specialist_area VARCHAR2(20)
);
The procedure would look like the one in the second (trigger) example, i.e. you don't need to reference the consultant_id column. As I run 11g XE on my laptop, I can't post the execution, but I'm sure you can do it yourself if necessary (and , of course, if you're on 12c).
Related
how to call function from package by creating own collection of same collection type which is being used in package? can we use our own created collection to call function from packages? getting error while calling function.
create or replace package pk
is
type e_list is table of emp%rowtype index by pls_integer;
function pro1 return e_list;
end;
create or replace package body pk
is
x number;
function pro1 return e_list
is
v_emp e_list;
begin
for x in 100..110 loop
select * into v_emp(x) from employees where employee_id=x;
end loop;
return v_emp;
end;
end;
to call function check below code plzz.
declare
type p_list is table of emp%rowtype index by pls_integer;
r_cur p_list;
x number;
begin
r_cur:=pk.pro1;
x:=r_cur.first;
for i in 1..10 loop
dbms_output.put_line(r_cur(x).salary);
x:=r_cur.next(x);
end loop;
end;
If you'll be using that type outside of the package, create it at SQL level. Something like this:
Sample data:
SQL> SELECT * FROM employees;
EMPLOYEE_ID ENAME SALARY
----------- ---------- ----------
100 SMITH 800
101 ALLEN 1600
102 WARD 1250
103 JONES 2975
Types:
SQL> CREATE OR REPLACE TYPE e_list_t IS OBJECT
2 (
3 employee_id NUMBER,
4 ename VARCHAR2 (20),
5 salary NUMBER
6 );
7 /
Type created.
SQL> CREATE OR REPLACE TYPE e_list IS TABLE OF e_list_t;
2 /
Type created.
Package specification and its body:
SQL> CREATE OR REPLACE PACKAGE pk
2 IS
3 FUNCTION pro1
4 RETURN e_list;
5 END;
6 /
Package created.
SQL> CREATE OR REPLACE PACKAGE BODY pk
2 IS
3 FUNCTION pro1
4 RETURN e_list
5 IS
6 v_emp e_list := e_list ();
7 BEGIN
8 SELECT e_list_t (employee_id, ename, salary)
9 BULK COLLECT INTO v_emp
10 FROM employees;
11
12 RETURN v_emp;
13 END;
14 END;
15 /
Package body created.
Testing:
SQL> DECLARE
2 r_cur e_list;
3 BEGIN
4 r_cur := pk.pro1;
5
6 FOR x IN 1 .. r_cur.LAST
7 LOOP
8 DBMS_OUTPUT.put_line (r_cur (x).ename || ': ' || r_cur (x).salary);
9 END LOOP;
10 END;
11 /
SMITH: 800
ALLEN: 1600
WARD: 1250
JONES: 2975
PL/SQL procedure successfully completed.
SQL>
First of all, I know the question is vague, so feel free to edit it if you can describe it better.
There are some sets of table like TEST_201812, TEST_201901, etc. . I have another table that stores these values:
TEST_DATE:
ID DATE
1 201810
2 201811
3 201812
4 201901
Now what I want is to select the tables mentioned above (e.g.TEST_201812) by using TEST_DATE. I know it's wrong, but something like this:
select * from TEST_(select DATE from TEST_DATE where ID = 1)
Does anyone know how to achieve this?
Seriously, such a data model is a disaster. If you want to keep separate months separately, use one - partitioned - table.
Anyway, here's one option of how to do that:
Sample tables and a function that returns refcursor:
SQL> create table test_201812 as select * From dept;
Table created.
SQL> create table test_date (id number, datum number);
Table created.
SQL> insert into test_date values (1, 201812);
1 row created.
SQL> create or replace function f_test (par_id in test_date.id%type)
2 return sys_refcursor
3 is
4 l_datum test_date.datum%type;
5 l_str varchar2(200);
6 l_rc sys_refcursor;
7 begin
8 select datum
9 into l_datum
10 from test_date
11 where id = par_id;
12
13 l_str := 'select * from test_' || l_datum;
14 open l_rc for l_str;
15 return l_rc;
16 end;
17 /
Function created.
Testing:
SQL> select f_test(1) from dual;
F_TEST(1)
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
DEPTNO DNAME LOC
---------- -------------- -------------
10 ACCOUNTING NEW YORK
20 RESEARCH DALLAS
30 SALES CHICAGO
40 OPERATIONS BOSTON
SQL>
I am trying to write a function that retrieves the number of hours that a user defined consultant has been assigned to a user defined project and the value should be returned to the plsql anonymous block calling the function. My procedure should update the number of hours that the consultant has been assigned to the project.
UPDATE: ok so I edited my code and finally got the function to return the correct value. Now all I need is to call my procedure to actually update the tables. The IF statement in my anonymous block doesnt seem to recognize the newtotal_hours. Any ideas???
NEW UPDATE ok so I got everything compiling and returning as it should be however the only problem I have left is that my procedure's update statement is causing a null value in the table where the updated newtotal_hours should replace it how can I fix this???
Here is my table:
project_consultant
(p_id number(6),
c_id number(6),
total_hours number(6)
);
and here is my WORKING UPDATED FUNCTION:
create or replace function return_num_hours (pid number, cid number)
return number is
totalhrs project_consultant.total_hours%type;
cursor c1 is select total_hours from project_consultant where p_id=pid and c_id=cid;
begin
open c1;
fetch c1 into totalhrs;
close c1;
return totalhrs;
end;
/
and finally heres my procedure:
create or replace procedure update_hours (proj_id number, consult_id number) is
change_in_hours number(6);
project_id project_consultant.p_id%type;
consultant_id project_consultant.c_id%type;
totalhours project_consultant.total_hours%type;
cursor c2 is select p_id, c_id, total_hours from project_consultant where p_id=proj_id and
c_id=consult_id;
begin
open c2;
fetch c2 into project_id, consultant_id, totalhours;
totalhours := totalhours + change_in_hours;
update project_consultant set total_hours = totalhours where p_id = proj_id and c_id = consult_id;
--commit;
close c2;
end;
/
my user-defined anonymous block to call the function and procedure..
declare
totalnumhours number(6);
change_in_hours number(6);
newtotal_hours number(6);
project_id number(6);
consultant_id number(6);
begin
consultant_id := &consult_id;
project_id := &proj_id;
change_in_hours := &change_in_hours;
totalnumhours := return_num_hours(project_id, consultant_id);
dbms_output.put_line(totalnumhours);
newtotal_hours := totalnumhours + change_in_hours;
dbms_output.put_line(newtotal_hours);
if newtotal_hours > 0 then
update_hours(project_id, consultant_id);
dbms_output.put_line('Consultant ' ||consultant_id||' Project '||project_id||':'||' changed planned hours from '||totalnumhours||'
to '||newtotal_hours);
else
dbms_output.put_line('Cannot update number of hours to a negative total');
end if;
commit;
exception
when no_data_found then
dbms_output.put_line('No such consultant or project');
end;
/
script output for consultant_id:101 project_id:1
SQL> select * from project_consultant
P_ID C_ID TOTAL_HOURS
---------- ---------- -----------
1 101
1 104 245
1 103 50
1 105 45
2 105 25
2 100 0
3 103 125
3 104 50
4 105 25
4 104 125
4 102 30
P_ID C_ID TOTAL_HOURS
---------- ---------- -----------
5 105 15
5 103 15
6 103 5
6 104 10
7 102 125
7 100 100
17 rows selected.
In your function you return third input parameter totalhours as a result return(totalhours);. Is it ok? I guess that you want to return value of totalhrs
I have PL/SQL function looking like:
FUNCTION get_agent_statistics ( id NUMBER
RETURN agent_stats_t
PIPELINED;
And I select from it (iBatis code):
SELECT * FROM table(pkg.get_agent_statistics(#id#))
How should I change this select if I'll remove PIPELINED statement from function?
If you'll get working compiled procedure without PIPELINED statement, you don't need to change your SELECT. See this - http://www.oracle-base.com/articles/misc/pipelined-table-functions.php
When you remove PIPELINED clause from the function declaration, function ceases to be a PIPELINED table function and as a result you will have to modify the body of the function to convert it to a TABLE function, if you still want to use it the from clause of the query, or a simple function, which you wont be able to use in the from clause of a query.
Addendum
Could I select something from non-pipelined function?
Yes, if you have a TABLE function, otherwise no. Here is a couple of examples:
-- prerequisites
SQL> create or replace type T_rows as object(
2 e_name varchar2(21),
3 e_lname varchar2(21)
4 )
5 /
Type created
SQL> create or replace type T_tab is table of t_rows
2 /
Type created
-- PIPELINED TABLE function
SQL> create or replace function GetEnames
2 return T_Tab
3 pipelined
4 is
5 l_etab t_tab := t_tab();
6 begin
7 for i in (select first_name
8 , last_name
9 from employees)
10 loop
11 pipe row(t_rows(i.first_name, i.last_name));
12 --l_etab.extend;
13 --l_etab(l_etab.last) := t_rows(i.first_name, i.last_name);
14 end loop;
15 return ;--l_etab;
16 end;
17 /
Function created
SQL> select *
2 from table(getenames)
3 where rownum <= 5;
E_NAME E_LNAME
--------------------- ---------------------
Steven King
Neena Kochhar
Lex De Haan
Alexander Hunold
Bruce Ernst
-- non-pipelined table function
SQL> create or replace function GetEnames
2 return T_Tab
3
4 is
5 l_etab t_tab := t_tab();
6 begin
7 for i in (select first_name
8 , last_name
9 from employees)
10 loop
11 --pipe row(t_rows(i.first_name, i.last_name));
12 l_etab.extend;
13 l_etab(l_etab.last) := t_rows(i.first_name, i.last_name);
14 end loop;
15 return l_etab;
16 end;
17 /
Function created
SQL> select *
2 from table(getenames)
3 where rownum <= 5;
E_NAME E_LNAME
--------------------- ---------------------
Steven King
Neena Kochhar
Lex De Haan
Alexander Hunold
Bruce Ernst
SQL>
I'm doing the following but it doesnt work
select package_name.function_name(param,param) from dual
I'm calling a function that returns a cursor so im guessing "from dual" is the problem
is there another way of doing it?
I presume you mean a Ref Cursor. This is a PL/SQL construct which acts as a pointer to a set of records returned by a query. This means it has to be interpreted by the client which runs the query. For instance, we can map a Ref Cursor to a JDBC or ODBC ResultSet.
There is certainly nothing wrong with your basic statement. Here is a function similar to your own:
SQL> desc get_emps
FUNCTION get_emps RETURNS REF CURSOR
Argument Name Type In/Out Default?
------------------------------ ----------------------- ------ --------
P_DNO NUMBER(2) IN
P_SORT_COL VARCHAR2 IN DEFAULT
P_ASC_DESC VARCHAR2 IN DEFAULT
SQL>
I can easily call this in a wider PL/SQL block:
SQL> declare
2 rc sys_refcursor;
3 begin
4 rc := get_emps(50);
5 end;
6 /
PL/SQL procedure successfully completed.
SQL>
However, SQL*PLus can handle CURSOR constructs natively:
SQL> select get_emps(50) from dual
2 /
GET_EMPS(50)
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
EMPNO ENAME JOB MGR HIREDATE SAL COMM DEPTNO
---------- ---------- --------- ---------- --------- ---------- ---------- ----------
8060 VERREYNNE PLUMBER 8061 08-APR-08 4000 50
8061 FEUERSTEIN PLUMBER 7839 27-FEB-10 4500 50
8085 TRICHLER PLUMBER 8061 08-APR-10 3500 50
8100 PODER PLUMBER 8061 3750 50
SQL>
This statement also runs in SQL Developer, although the result set is laid out in an ugly fashion.
So, if you are having problems with your function, the questions are:
What client environment are you using?
In what precise fashion does it "not work"? Please describe the observed behaviour, including any error messages?
Also give us environment details such as the version of the database, the OS, etc.
Having read your other question on this topic I thought the problem might be due to the use of a User-Defined Ref Cursor (rather than the built-in). However, that doesn't make any difference. This packaged function:
SQL> create or replace package emp_rc_utils as
2
3 type emp_rc is ref cursor return emp%rowtype;
4
5 function get_emps
6 ( p_dno in emp.deptno%type
7 )
8 return emp_rc;
9 end;
10 /
Package created.
SQL> create or replace package body emp_rc_utils as
2
3 function get_emps
4 ( p_dno in emp.deptno%type
5 )
6 return emp_rc
7 is
8 return_value emp_rc_utils.emp_rc;
9 begin
10
11 open return_value for select * from emp where deptno = p_dno;
12
13 return return_value;
14 end get_emps;
15
16 end emp_rc_utils;
17 /
Package body created.
SQL>
Still works...
SQL> declare
2 rc sys_refcursor;
3 begin
4 rc := emp_rc_utils.get_emps(50);
5 end;
6 /
PL/SQL procedure successfully completed.
SQL> select emp_rc_utils.get_emps(50) from dual
2 /
EMP_RC_UTILS.GET_EMP
--------------------
CURSOR STATEMENT : 1
CURSOR STATEMENT : 1
EMPNO ENAME JOB MGR HIREDATE SAL COMM DEPTNO
---------- ---------- --------- ---------- --------- ---------- ---------- ----------
8085 TRICHLER PLUMBER 8061 08-APR-10 3500 50
8060 VERREYNNE PLUMBER 8061 08-APR-08 4000 50
8061 FEUERSTEIN PLUMBER 7839 27-FEB-10 4500 50
8100 PODER PLUMBER 8061 3750 50
SQL>
You can do this via a refcursor call or populate a user defined table and return it as follows:
create or replace
function getRef return sys_refcursor
is
l_ref sys_refcursor;
begin
open l_ref for
select 1 a, 'a' c from dual
union all
select 2 a, 'b' c from dual
union all
select 3 a, 'c' c from dual
union all
select 4 a, 'd' c from dual;
return l_ref;
end getRef;
/
select getref() from dual;
GETREF()
--------
A C
---------------------- -
1 a
2 b
3 c
4 d
--you'll notice this isn't the most user-friendly result set if you look at it in SQL Developer or whatno
--drop function getRef;
you can also use the 'table' if you are passing back a table collection as such
create or replace type lookup_row as
object ( a number, c varchar2(20) );
/
create or replace type lookups_tab as
table of lookup_row;
/
create or replace
function getUserDefinedTableType return lookups_tab
is
lTestTypeTable lookups_tab;
begin
SELECT lookup_row(a,c)
bulk collect INTO lTestTypeTable
from
(select 1 a, 'a' c from dual
union all
select 2 a, 'b' c from dual
union all
select 3 a, 'c' c from dual
union all
select 4 a, 'd' c from dual);
return lTestTypeTable;
end getUserDefinedTableType;
/
select * from table(getUserDefinedTableType());
--this returns it in a more user friendly manner
--http://www.oreillynet.com/pub/a/network/2003/01/22/feuerstein.html?page=2
--http://stackoverflow.com/questions/3150137/converting-oracle-query-into-user-defined-types-in-pl-sql/3152885#3152885
A C
---------------------- --------------------
1 a
2 b
3 c
4 d
have you tried:
myCursor := package_name.function_name(param,param);
this would have to be from within a test block or a stored procedure.