PLSQL function wont return salary where name of the employee is passed in as a parameter - sql

Question

Here is my PLSQL function:
Create or Replace FUNCTION getEmpSalary(p_name in VARCHAR)
Return NUMBER IS
l_return_salary;
l_salary;
table_salary NUMBER;
BEGIN
Select salary into table_salary from AlphaCoEmp where p_name = p_name;
return l_return_salary;
END;
/
show errors;
I have built a table that holds the following tuples:
NAME TITLE SALARY
------------------------- --------------------
Wong 91296
Utech 82058
Vega 86858
Weiser 79771
and am trying to write a PLSQL function to return the salary where the name is passed as parameter.
This is how I am passing as parameter: Note: param1 is the name chosen.
exec setEmpSalary(Utech);
I am getting the following error(s):
ERROR at line 1:
ORA-06550: line 1, column 20:
PLS-00201: identifier 'UTECH' must be declared
ORA-06550: line 1, column 7:
PL/SQL: Statement ignored
I am unsure as to how this error is being created and could use some help fixing the error. Thanks for your time.

Answer 1

This is what you might/should have done:
First, a test case:
SQL> create table test
2 (ename varchar2(10),
3 salary number
4 );
Table created.
SQL> insert into test (ename, salary)
2 select 'Wong' , 91296 from dual union
3 select 'Utech', 82058 from dual;
2 rows created.
A function:
note the way I declared the parameter and the return value - both of them use the appropriate datatype of the column they reference
I used the MAX function when selecting the salary. Why? Because, if you pass an invalid employee name, function would return NO_DATA_FOUND error. Another - and probably a better way - is to handle that with the EXCEPTION section, such as
begin
select ...
exception
when no_data_found then return null;
end;
Though, MAX is a quick and dirty solution that saves you from some typing during the testing phase of your code.
SQL> create or replace function get_emp_salary(p_ename in test.ename%type)
2 return test.salary%type
3 is
4 retval test.salary%type;
5 begin
6 select max(t.salary)
7 into retval
8 from test t
9 where t.ename = p_ename;
10
11 return retval;
12 end;
13 /
Function created.
OK, let's see what it does:
SQL> select get_emp_salary('Utech') from dual;
GET_EMP_SALARY('UTECH')
-----------------------
82058
SQL> select get_emp_salary('Littlefoot') from dual;
GET_EMP_SALARY('LITTLEFOOT')
----------------------------
SQL>
Seems to be OK.
In your function, there are 3 local variables. The first two of them are invalidly declared (no datatype). SELECT then selects salary into "table_salary", but you're returning "l_return_salary" which is always NULL - why did you do that?
As of the error you got ("PLS-00201: identifier 'UTECH' must be declared"), it means that you passed the parameter value without single quotes, as you're passing employee name (which is a string).
Also, you're executing setEmpSalary, while the function is get (was it a typo?).

Answer 2

You have problem with your calling code -- UTECH needs to be declared -- or you need to put single quotes around it.
More importantly, the code for the function is wrong, because it confuses a parameter name and a column name.
I think you want:
Create or Replace FUNCTION getEmpSalary (in_p_name in VARCHAR)
Return NUMBER IS
l_return_salary NUMBER;
BEGIN
Select salary into l_return_salary
from AlphaCoEmp ace
where ace.p_name = in_p_name;
return(l_return_salary);
END;

Answer 3

Try
Create or Replace FUNCTION getEmpSalary(p_name in VARCHAR)
Return NUMBER IS
l_return_salary number;
BEGIN
Select salary
into l_return_salary
from AlphaCoEmp
where name = p_name;
return l_return_salary;
exception
when others then
return 0;
END;