Excel VBA - Select All Columns & Rows After Last Occupied Column & Row - vba

Question

I'm trying to figure out the code that identifies the last occupied column in the sheet then deletes all columns after that. I'm also trying to figure out the code that identifies the last occupied row in the sheet then delete all rows after that.
So far I've got the idea that I will need to use Rows.Count function but I'm having trouble getting it to select the entire rows after the last occupied row. Same for columns... This is what I've come up with so far which only identifies the last occupied row. Does anyone know how to get it to now select the entire rows after this? And similarly for the entire columns? I can't seem to figure out the code to select the last occupied column like I can with rows... Thank you in advance
Rows:
Sheets("ppCopy").Cells(Rows.Count, 1).End(xlUp).Row

Answer 1

You need to read the code and try to make sense of it and the answer will come to you.
Break down what you already know.
Sheets("ppCopy").Cells(Rows.Count, 1).End(xlUp).Row
Rows.Count = Last Available Row
End(xlUp) = move UP from the last available row (Rows.Count) to the last used row.
How do you get the column then?
Sheets("ppCopy").Cells(1, Columns.Count).End(xlToLeft).Column
Columns.Count = Last Available Column
End(xlToLeft) = Move Left from the last available column (Columns.Count) to the last used Column.
Here is how to delete unused Rows and Columns:
Sub deleteUnused()
Dim lastRow As Long, lastColumn As Integer 'there are a lot of rows compared to columns
Dim lastLetter As String, firstLetter As String
Set wk = ThisWorkbook
With wk.Sheets("Sheet1")
'Get last used rows and columns based on valued from Column A and Row 1
lastRow = .Cells(Excel.Rows.Count, 1).End(Excel.xlUp).Row
lastColumn = .Cells(1, Excel.Columns.Count).End(Excel.xlToLeft).Column
'Delete Rows
.Rows("" & (lastRow + 1) & ":" & Excel.Rows.Count & "").EntireRow.Delete Shift:=xlUp
'Delete columns, tricky because you need the Column Letters instead of the numbers
lastColumn = lastColumn + 1
firstLetter = Split(.Cells(, lastColumn).Address, "$")(1)
lastLetter = Split(.Cells(, Excel.Columns.Count).Address, "$")(1)
.Columns("" & firstLetter & ":" & lastLetter & "").EntireColumn.Delete Shift:=xlLeft
End With
End Sub

Answer 2

J Doe
Here is a code that will search for the value in any cell on any column and then select and delete all rows after that and do the same for the columns. No a very technic or something but will do the work and also give you some ideas. It will also include formulas that display empty cells.
Hope this help.
Sub DeleteRowAndColumns()
With ThisWorkbook.Sheets("ppCopy")
'find any cell no empty in a row in any row
.Cells.Find(What:="*", SearchOrder:=xlRows, SearchDirection:=xlPrevious, LookIn:=xlValues).Offset(1, 0).EntireRow.Select
'select all the rows
.Range(Selection, Selection.End(xlDown)).Select
Selection.Delete ' clear all the rows
'find the last value in any column
.Cells.Find(What:="*", SearchOrder:=xlColumns, SearchDirection:=xlPrevious, LookIn:=xlValues).Offset(0, 1).EntireColumn.Select
'select columns
.Range(Selection, Selection.End(xlToRight)).Select
Selection.Delete 'clear columns
End With
End Sub