What is the opposite command of CleanImage() - dm-script

Question

CleanImage( BasicImage )
allows to delete an image without getting the dialog: "Do you want to save ..."
Apart from adding zero to the whole image (8k by 8k), is there a counter part? Like:
DirtyImage( BasicImage )
Thanks!

Answer 1

No, such a command does not exist, but it also isn't really useful.Any action on an imageDocument will automaticaly mark it dirty (i.e. needs to be saved), so you can easily do this by f.e. adding/removing a tag; setting a pixelvalue temporarily; moving the window, etc.
The command CleanImage() is just a convenience feature really. The actual property "is different from stored file" is a property of the the ImageDocument, the stuff that gets saved to disc.
As a consequence, the command isn't really doing anything to images which do not have an ImageDocument, i.e. image variables which have never been shown, saved, or had ImageGetOrCreateImageDocument() called on them. You can see this here:
image img := RealImage( "test", 4, 100, 100 )
If ( TwoButtonDialog("Show?","Yes","No") )
img.ShowImage()
If ( TwoButtonDialog("Try closing before cleaning?","Yes","No") )
img.CloseImage()
else
{
img.CleanImage()
img.CloseImage()
}
The command really matches to:
void ImageDocumentClean( ImageDocument imgDoc )
and the command to check if an imageDocument needs saving is
Boolean ImageDocumentIsDirty( ImageDocument img_doc )
So, more typically one would use these commands instead, as I do in the scripts below.
The following script shows how you can easily "dirty" an imageDocument just by re-setting one of the pixels value. Note that this script works independently of having the image displayed, because we explicitly create the ImageDocument.
Result( "\n Create Image... ")
image img := RealImage( "test", 4, 100, 100 )
Result( "\n Get it's ImageDocument... ")
imageDocument doc = img.ImageGetOrCreateImageDocument()
Result( "\n Is it dirty? --> " + (doc.ImageDocumentIsDirty()?"Yes, dirty":"No, clean"))
Result( "\n Clean it!" )
doc.ImageDocumentClean()
Result( "\n Is it dirty? --> " + (doc.ImageDocumentIsDirty()?"Yes, dirty":"No, clean"))
Result( "\n Make it dirty by setting the first pixel value to the value it has..." )
img.SetPixel(0,0,img.GetPixel(0,0))
Result( "\n Is it dirty? --> " + (doc.ImageDocumentIsDirty()?"Yes, dirty":"No, clean"))
However, I am curious in when such a functionality would ever be needed?