Excel VBA: Cannot delete multi columns by using if statement and for loop - vba

Question

Background & purpose.
I want to delete multi columns in my "sheet1" based on specific column header.
For example: if column name = "First Name", "Surname", "DoB", "Gender", "Year"
Then delete entire of column.
And I use vba to do that.
Button "Execute" in "Execution" sheet
Data is saved in "Sheet1".
Click on "Execute" button, macro will be executed and edit data in "sheet1".
Here is my code
Sub SPO_EditDocument_BUttonClick()
'Declare constant variable
Dim CellValue As String
'Edit SPO Documents.
'Consider worksheet"SPO"
With Worksheets("Sheet1")
'1. Loop and delete unnecessary columns
LastCol = Sheets("Sheet1").Cells.Find(What:="*", After:=[A1], SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious).Column
For i = 1 To LastCol
On Error Resume Next
CellValue = Sheets("Sheet1").Cells(1, i) 'Get Column header
If CellValue = "Firstname" Then
Sheets("Sheet1").Columns(i).EntireColumn.Delete
ElseIf CellValue = "Surname" Then
Sheets("Sheet1").Columns(i).EntireColumn.Delete
ElseIf CellValue = "DoB" Then
Sheets("Sheet1").Columns(i).EntireColumn.Delete
ElseIf CellValue = "Gender" Then
Sheets("Sheet1").Columns(i).EntireColumn.Delete
ElseIf CellValue = "Year" Then
Sheets("Sheet1").Columns(i).EntireColumn.Delete
End If
Next i
End With 'End to process Worksheets
Application.ScreenUpdating = True
End Sub
Sample data table in sheet1
Problem: When I execute my macro by clicking on button "Execute", just only 1 column is deleted at that time. Next click → next column is deleted (just can delete 1 column by one click).
Question: Why I can not delete all columns by 1 click with my code?
What is the problem in this case?
Any help would be highly appreciated.
Thank you so much for your attentions.
Insert new columns before found cells

Answer 1

Loop through the columns in reverse order. To do that, change your line:
For i = 1 To LastCol
to:
For i = LastCol to 1 Step -1

Answer 2

another fast way
Option Explicit
Sub SPO_EditDocument_BUttonClick()
Dim colNames As Variant, colName As Variant, actualColNames As Variant, foundColName As Variant
Dim colsToDelete As String
colNames = Array("Firstname", "Surname", "DoB", "Gender", "Year") ' build a list of column headers to be deleted
With Worksheets("Sheet1") ' reference data sheet
actualColNames = Application.Index(.Range("A1", .Cells(1, .Columns.count).End(xlToLeft)).Value, 1, 0) ' collect referenced sheet actual column headers
For Each colName In colNames ' loop through your column headers to be deleted list
foundColName = Application.Match(colName, actualColNames, 0) ' try finding current header to be deleted in actual headers list
If Not IsError(foundColName) Then colsToDelete = colsToDelete & Columns(foundColName).Address(False, False) & " " 'if found update columns to be deleted index list
Next
If colsToDelete <> "" Then .Range(Replace(Trim(colsToDelete), " ", ",")).EntireColumn.Delete ' if columns to be deleted index list not empty, then delete thsoe columns
End With

Answer 3

A faster way to delete multiple columns will be to use a Range object, in my code it's DelRng, which merges all Columns that pass your criteria to be deleted - using the Union function. So at the end, you just use the Delete function which takes a long time to process just once.
You can replace your multiple ElseIfs with a Select Case.
All objects which are nested in your With Worksheets("Sheet1") don't need to have With Worksheets("Sheet1") again, just use the . as a prefix to all Cells and Range objects.
You can have the much shorter, and faster code version like the code below:
Modified Code
Sub SPO_EditDocument_BUttonClick()
'Declare constant variable
Dim CellValue As String
Dim DelRng As Range
'Edit SPO Documents.
'Consider worksheet"SPO"
Application.ScreenUpdating = False
With Worksheets("Sheet1")
'1. Loop and delete unnecessary columns
LastCol = .Cells.Find(What:="*", After:=[A1], SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column
For i = 1 To LastCol
CellValue = .Cells(1, i) 'Get Column header
Select Case CellValue
Case "Firstname", "Surname", "DoB", "Gender", "Year"
If Not DelRng Is Nothing Then
Set DelRng = Application.Union(DelRng, .Columns(i))
Else
Set DelRng = .Columns(i)
End If
Case Else
' Do nothing
End Select
Next i
End With 'End to process Worksheets
' if there's at least 1 column in DelRng >> delete the entire range (all columns) in 1-shot
If Not DelRng Is nothign Then DelRng.Delete
Application.ScreenUpdating = True
End Sub