VBA loop merging cells in specific range - vba

Question

I have a specified range and want to merge the cells A-D per row. I'm not sure which loop would be the best, and have messed around with different ones and the problem I have run into, is either an object-defined error or merging the entire range into one cell.
Sub Merge()
Dim EndRangeRE As Range
Dim EndRangeNRE As Range
Dim rngall As Range
Dim StartRangeNRE As Range
Dim StartRangeRE As Range
Dim looprng As Range
Sheets("{Activity} 7300-1input template").Activate
Set rngall = Sheets("{Activity} 7300-1input template").UsedRange
Set EndRangeRE = rngall.Find(What:="10. Other Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set EndRangeNRE = rngall.Find(What:="Recurring Costs", LookIn:=xlValues,LookAt:=xlWhole, MatchCase:=True)
Set StartRangeNRE = rngall.Find(What:="Non-Recurring Costs",LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set StartRangeRE = rngall.Find(What:="Recurring Costs", LookIn:=xlValues,LookAt:=xlWhole, MatchCase:=True)
Set looprng = Sheets("{Activity} 7300-1input template").Range(StartRangeNRE, EndRangeRE)
For Each Row In looprng
Cells(0, 4).Merge
Next Row
End Sub
This one gives me an error and I'm not sure how to specify to do each row, A:D merge and next row. Would it be a do loop? I'm very open to the easiest way to make this happen so suggestions are gladly welcomed (I'm not too experienced in coding so anything to help me learn!). Thanks!

Answer 1

maybe you're after this:
Option Explicit
Sub Merge()
Dim EndRangeRE As Range, StartRangeNRE As Range
Dim myRow As Range
With Sheets("{Activity} 7300-1input template")
With .UsedRange
Set EndRangeRE = .Find(What:="10. Other Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set StartRangeNRE = .Find(What:="Non-Recurring Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
End With
For Each myRow In .Range(StartRangeNRE, EndRangeRE).Rows
.Rows(myRow.row).Resize(, 4).Merge
Next
End With
End Sub
where I got rid of unused variables and use some With-End With block to reference multiple reference of the same object

Answer 2

This will merge A through D for 100 rows:
Sub ytrewq()
For i = 1 To 100
Range("A" & i & ":D" & i).MergeCells = True
Next i
End Sub
EDIT#1:
Sub ytrewq()
For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
Range("A" & i & ":D" & i).MergeCells = True
Next i
End Sub

Answer 3

Try This code :
Sub test()
'Get The Last non empty row
lastRow = ThisWorkbook.Sheets("YourSheetName").Cells(Rows.Count, 1).End(xlUp).Row
For i = 1 To lastRow
ThisWorkbook.Sheets("YourSheetName").Range("A" & i & ":D" & i).Merge
Next i
End Sub

Answer 4

The code below incoropates Merging cells in columns "A:D" in your looprng range.
Code
Option Explicit
Sub Merge()
Dim EndRangeRE As Range
Dim EndRangeNRE As Range
Dim rngall As Range
Dim StartRangeNRE As Range
Dim StartRangeRE As Range
Dim looprng As Range
' 2 added object variables
Dim Sht As Worksheet
Dim myRow As Range
' set your worksheet object, don't need to Activate it
Set Sht = ThisWorkbook.Sheets("{Activity} 7300-1input template")
Set rngall = Sht.UsedRange
Set EndRangeRE = rngall.Find(What:="10. Other Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set EndRangeNRE = rngall.Find(What:="Recurring Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set StartRangeNRE = rngall.Find(What:="Non-Recurring Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set StartRangeRE = rngall.Find(What:="Recurring Costs", LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=True)
Set looprng = Sht.Range(StartRangeNRE, EndRangeRE)
' merge cells in columns "A:D" in your range
For Each myRow In looprng.Rows
Sht.Range(Sht.Range("A" & myRow.Row), Sht.Range("D" & myRow.Row)).Merge
Next myRow
End Sub