awk doesn't assign variable and uses $0 instead - awk

Question

I'm using the following /bin/sh code to parse the output of apt show and print only the names of the packages matching the second pattern, but it doesn't work. Instead it outputs the pattern itself in both prints as if the variable pac was never assigned and instead uses $0 in all cases.
apt show vim peazip 2> /dev/null | \
awk '
/^Package:/ {
pac = substr($0, 10);
print "found name "$pac;
}
/APT-Sources: \/var\/lib\/dpkg\/status/ {
print "bingo "$pac;
}
'
Output: (gawk on Ubuntu)
found name Package: vim
found name Package: peazip:i386
bingo APT-Sources: /var/lib/dpkg/status
What am I doing wrong?

Answer 1

awk is C-like in that you don't use $ to get the value of a variable:
$ awk 'BEGIN { x=42; print x }'
42
I think of $ in awk as an operator that fetches the value of the field number identified by the expression after $. For example, the 2nd field is $2, the last field is $NF where NF is a variable whose value is the number of fields in the current record.
Now, why does $pac act like $0?
awk, in a numeric context, treats an arbitrary string like this: take the string, truncate it at the first non-digit character; if the truncation results in an empty string, numerically treat the string as zero.
$ echo "foo bar" | awk '{x="2cats"; print $x}'
bar
The value of pac does not start with digits, so numerically is has value zero, then you apply the $ "operator" to get $0, or the whole string
$ echo "foo bar" | awk '{x="no-cats"; print $x}'
foo bar

Answer 2

Awk does not require $ in front of variable names :) your code should look like this instead:
apt show vim peazip 2> /dev/null | \
awk '
/^Package:/ {
pac = substr($0, 10);
print "found name "pac;
}
/APT-Sources: \/var\/lib\/dpkg\/status/ {
print "bingo "pac;
}
'