Change the case of a Range text and type it - vba

Question

Possible scenario, let say we created a Range Object containing the following line:
Speculative BUY, FV: EGP19.59
Now I want to split the Range Object into two parts by ", " as delimiter so that the given Range will change into two Ranges containing "Speculative BUY" and ", FV: EGP19.59" (Two separate range).
Now I need to change the case of only the first range containing "Speculative BUY" into "Speculative Buy" using:
.Case = wdTitleWord
Previously I am using .Find to change the Ranges in the following code (this is not complete code as it is only changing the Range R, not splitting it into two):
Sub Range_into_Ranges()
selection.EndKey Unit:=wdLine
selection.MoveUp Unit:=wdParagraph, COUNT:=1, Extend:=wdExtend
Dim R, F As Word.Range
Set R = selection.Range
Set F = R.Duplicate
With F.Find
.Text = ", "
.Forward = True
.Wrap = wdFindStop
.Execute
End With
If F.Find.Found Then
R.SetRange Start:=R.Start, _
End:=F.Start
R.Case = wdTitleWord
Else
End If
End Sub
Note: There may be other ways of producing the same results. you are free to advice me another simple code.

Answer 1

You can assign a case to a Range using the WdCharacterCase enumeration. For title case:
R.Case = wdTitleWord
Put into the context of your sample code, something like as follows. I did some tweaking:
My version assumes you want to work with the paragraph where the selection currently is, which is why I commented out your first two lines
In VBA you need to declare the data type of every variable, otherwise it's a Variant. So: Dim R As Word.Range
VBA provides the Split function to divide up a string according to a delimiter. I use this to get the term to search, so that you can get the Range directly
I found when setting Title Case on text that has ALL CAPS that it doesn't reduce upper case to lower case. But first applying lower case, then title case, does work.
Sample code
Sub Range_into_Ranges()
' Selection.EndKey Unit:=wdLine
' Selection.MoveUp Unit:=wdParagraph, Count:=1, Extend:=wdExtend
Dim R As word.Range, F As word.Range
Dim sTerm As String, bFound As Boolean
Set R = Selection.Paragraphs(1).Range
R.MoveEnd wdCharacter, -1 'Trim off the paragraph mark
sTerm = R.Text
sTerm = Split(sTerm, ",")(0)
Set F = R.Duplicate
With F.Find
.Text = sTerm
.Forward = True
.wrap = wdFindStop
bFound = .Execute
End With
If bFound Then
F.Case = wdLowerCase
F.Case = wdTitleWord
Else
End If
End Sub