Iterate li in html with vba - vba

Question

I cant seem to locate an answer to this anywhere through searches...
I am trying to iterate through a list on a webpage using vba and then use the data in excel.
Accessing the webpage is fine, locating the correct div is fine but I cannot find how to iterate through the list.
What I am trying is:
Sub getdata()
Dim ie As InternetExplorer
Dim html As HTMLDocument
Set ie = New InternetExplorer
ie.Visible = False
ie.navigate "http://www.springfieldeducationalfurniture.co.uk/products/60-Chair-Trolley/11116/"
Do While ie.READYSTATE <> READYSTATE_COMPLETE
Application.StatusBar = "Attempting connection ..."
DoEvents Loop
Set html = ie.document
Set ie = Nothing
Application.StatusBar = ""
Dim content Set content = html.getElementsByClassName("tabs__content")
For Each bullet In content
'tried this
IHtml = bullet.innerHTML'this gives the whole div not sure how to convert to a string
'and this but get "Run-time error '438': Object doesn't support this property or method"
IHtml = bullet.getElementsByTagName("li")
Next
End Sub
They HTML I am after is as follows, I am wanting to iterate through the <ul> in the <div class="tabs__content"> and assign the content i.e. "Requires simple self assembly" to a cell in excel (once I read the data from the list, the rest is easy):
<div class="tabs">
<div class="container">
<ul class="tabs__nav">
<li class="is-active background-grey-lighter">
Description
</li>
<li class="background-grey-light">
Delivery
</li>
</ul>
</div>
<div class="tabs__tab tabs__tab--product-info is-active">
<div class="tabs__title">
Information
</div>
<div class="tabs__content">
<div class="container">
<p>
60 Chair Trolley</p>
<ul>
<li>
Requires simple self assembly</li>
<li>
Non marking wheels </li>
<li>
Heavy duty lockable castors</li>
<li>
Black frame</li>
<li>
Vertical / hanging chair storage</li>
<li>
Does not fit through a single doorway</li>
<li>
Fits through double doors when fully loaded</li>
<li>
Dimensions: W780 x L1770 x H1340mm</li>
</ul>
<p>
Code: Y16527<br />
</p>
</div>
</div>
</div>
<div class="tabs__tab tabs__tab--product-info ">
<div class="tabs__title">
Delivery
</div>
<div class="tabs__content">
<div class="container">
<p>
Please <span style="color: rgb(0, 0, 255);">contact us</span> for delivery information.</p>
</div>
</div>
</div>
</div>

Answer 1

And this targets the class you mentioned. Requires reference to HTML Object library and Microsoft XML (your version)
Option Explicit
Sub Getinfo2()
Dim http As New XMLHTTP60
Dim html As New HTMLDocument
With http
.Open "GET", "http://www.springfieldeducationalfurniture.co.uk/products/60-Chair-Trolley/11116/", False
.send
html.body.innerHTML = .responseText
End With
Dim posts As MSHTML.IHTMLElementCollection
Dim post As MSHTML.IHTMLElement
Set posts = html.getElementsByClassName("tabs__content")(0).getElementsByTagName("li")
For Each post In posts
Debug.Print post.innerHTML
Next post
End Sub
Output:
This gets the html for all the li elements
Option Explicit
Sub Getinfo2()
Dim http As New XMLHTTP60
Dim html As New HTMLDocument
With http
.Open "GET", "http://www.springfieldeducationalfurniture.co.uk/products/60-Chair-Trolley/11116/", False
.send
html.body.innerHTML = .responseText
End With
Dim posts As MSHTML.IHTMLElementCollection
Dim post As MSHTML.IHTMLElement
Set posts = html.getElementsByTagName("li")
For Each post In posts
Debug.Print post.innerHTML
Next post
End Sub

Answer 2

Here is an alternative option that doesn't require any reference's to library's (Late binding). It also show a different way of looping through the class, as well as the LI's.
Sub getData()
Dim ie As Object
Dim li As Object
Dim tabsClass As Object
'Late Binding
Set ie = CreateObject("InternetExplorer.Application")
On Error GoTo Catch
ie.Visible = False
ie.navigate "http://www.springfieldeducationalfurniture.co.uk/products/60-Chair-Trolley/11116/"
While ie.ReadyState <> 4 Or ie.Busy: DoEvents: Wend
'LOOP EACH CLASS ELEMENT
For Each tabsClass In ie.Document.getElementsByClassName("tabs__content")
'LOOP EACH LI WITHIN THAT CLASS
For Each li In tabsClass.getElementsByTagName("li")
Debug.Print li.innertext
Next li
Next tabsClass
'CLOSE INSTANCE OF IE
Catch:
ie.Quit
Set ie = Nothing
End Sub