Web scraping with another browser - vba

Question

So I'm new to vba and i am try to get price which site is Steam. But i cant use steam because internet explorer doesnt open steam. (its opening but drawmenü not working, i cant sign in my account, the site isn't responding my clicks.) 2 days ago it was working well. but google chrome and edge works well they dont have problem.
Not loading well:
When i click the sign in button its doing nothing.
Some pages not loading
Draw menüs not opening, so i cant change language sorry for that its not english
i reinstall my internet explorer, i did format but its same. So i dont want to use internet explorer. What should i do, i cant use IE for scraping data.
There is my getting price code:
Sub SPrice1()
Dim objIE As InternetExplorer
Dim itemEle As Object
Dim Des1 As String
Dim y As Integer
Dim x As Integer
Set objIE = New InternetExplorer
y = 1
For x = 1 To 21
objIE.navigate "http://steamcommunity.com/market/search?appid=578080#p" & x & "x_name_asc"
Do While objIE.Busy = True Or objIE.readyState <> 4: DoEvents: Loop
MsgBox "Checking"
For Each itemEle In objIE.document.getElementsByClassName("market_listing_row_link")
Prc1 = itemEle.getElementsByClassName("market_listing_right_cell market_listing_their_price")(0).getElementsByTagName("span")(1).textContent
Sheets("Sheet1").Range("E" & y).Value = Prc1
y = y + 1
Next
Next x
objIE.Quit
End Sub

Answer 1

Here is an example of scraping one link,using Selenium Basic, which you can easily adapt into a loop. After installing you need to add a reference to Selenium Type Library.
CSS Selectors:
I use the CSS "." - className selector.
So, .market_listing_game_name means get all the elements who className matches the string after the ".". Same principle applies for the others. The last selector is a chained selector of className normal_price within elements with a className of market_table_value.
Example CSS selector (Sample of results):
Example from page:
Examples from code output:
Note: These numbers are constantly fluctuating.
VBA Code:
Option Explicit
Public Sub GetInfoSel()
Dim d As WebDriver
Set d = New ChromeDriver
Const url = "https://steamcommunity.com/market/search?appid=578080#p1_name_asc"
With d
.Start "Chrome"
.Get url
Dim gameNames As Object, itemNames As Object, quantities As Object, normalPrices As Object
Set gameNames = .findElementsbyCSS(".market_listing_game_name")
Set itemNames = .findElementsbyCSS(".market_listing_item_name")
Set quantities = .findElementsbyCSS(".market_listing_num_listings_qty")
Set normalPrices = .findElementsbyCSS(".market_table_value .normal_price")
Dim currentItem As Long
For currentItem = 1 To gameNames.Count
Debug.Print "Game: " & gameNames(currentItem).Text
Debug.Print "Item: " & itemNames(currentItem).Text
Debug.Print "Qty: " & quantities(currentItem).Text
Debug.Print "Normal Price - " & normalPrices(currentItem).Text
Next currentItem
.Quit
End With
End Sub

Answer 2

this task can be done very easily by using python beautifulsoup https://www.crummy.com/software/BeautifulSoup/bs4/doc/