Find Data Between Dates and Copy Them to New Workbook - vba

Question

I am trying to create a report feature for a machine downtime tracker I have created for work. I have a userform which asks for the machine name, as well as the date range they would like to get data from. I would like this to open the workbook where the data is stored, capture the data they want and copy it to a new workbook.
After searching on here for a while I was able to put something together with the autofilter feature, but I cannot get any of the data to show up on the new sheet. I think it may have something to do with the Date, but I can't seem to figure it out. Here is my code:
Public Sub cmdSubmit_Click()
Dim wb1 As Workbook, wb2 As Workbook
Dim ws1 As Worksheet, ws2 As Worksheet
Dim copyFrom As Range
Dim lRow As Long
Dim startDate As Date, endDate As Date
Set wb1 = Workbooks.Open("FILEPATH")
'~~> Checks to see what sheet the data should be copied from based on the combo box entry.
If Me.cmboWorkCenter.Value = "Machine1" Then
Set ws1 = wb1.Sheets("Machine1")
ElseIf Me.cmboWorkCenter.Value = "Machine2" Then
Set ws1 = wb1.Sheets("Machine2")
ElseIf Me.cmboWorkCenter.Value = "Machine3" Then
Set ws1 = wb1.Sheets("Machine3")
ElseIf Me.cmboWorkCenter.Value = "Machine4" Then
Set ws1 = wb1.Sheets("Machine4")
ElseIf Me.cmboWorkCenter.Value = "Machine5" Then
Set ws1 = wb1.Sheets("Machine5")
ElseIf Me.cmboWorkCenter.Value = "Machine6" Then
Set ws1 = wb1.Sheets("Machine6")
Else
MsgBox "ERROR"
Unload Me
End If
startDate = Me.txtStartTime.Value
endDate = Me.txtEndTime.Value
With ws1
'~~> Remove any filters
.AutoFilterMode = False
lRow = .Range("B" & .Rows.Count).End(xlUp).Row
With .Range("B1:B" & lRow)
.AutoFilter Field:=2, Criteria1:=">=" & startDate, Operator:=xlAnd, Criteria2:="<=" & endDate
Set copyFrom = .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow
End With
''~~> Remove any filters
.AutoFilterMode = False
End With
'~~> Destination File
Set wb2 = Workbooks.Add
Set ws2 = wb2.Worksheets("Sheet1")
With ws2
If Application.WorksheetFunction.CountA(.Cells) <> 0 Then
lRow = .Cells.Find(What:="*", _
After:=.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
Else
lRow = 1
End If
copyFrom.Copy .Rows(lRow)
End With
wb1.Close
End Sub
Any help would be appreciated!

Answer 1

You are working solely with column B, specifically .Range("B1:B" & lRow). The field isn't 2 it is 1 since there is only one column in .Range("B1:B" & lRow).
With .Range("B1:B" & lRow)
.AutoFilter Field:=1, Criteria1:=">=" & startDate, Operator:=xlAnd, Criteria2:="<=" & endDate
Set copyFrom = .Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow
End With