How can I get the text after the second bracket in VBA? - vba

Question

Trying to get the value after the second bracket, I try to work with this one i created but it's not working properly and getting more complicated while I am having more brackets in each row.. Any idea. I uploaded couple images to understand the input and output.
Sub stringtest()
Dim text As String, i As Long, firstbracket As Long, secondbracket As Long
Dim extractTest As String, y As Long
y = 1
For i = 1 To 10
text = Worksheets("Sheet1").Cells(i, 1).Value
firstbracket = InStr(1, text, "[")
secondbracket = InStr(firstbracket + 1, text, "]")
extractTest = Mid(text, firstbracket + 1, secondbracket)
Worksheets("Sheet1").Cells(y, 2).Value = extractTest
y = y + 1
Next i
End Sub

Answer 1

Try splitting by the second bracket, then using Left() to determine the length of the string
Option Explicit
Public Sub GetStringAfter2ndBracketInSequentialColumns()
Dim i As Long, j As Long, nextRow As Long, ub As Long, lr As Long
Dim extract As Variant, found As Long, nextCol As Long
With Sheet1
lr = .UsedRange.Rows.Count
nextRow = 1
nextCol = 2
For i = 1 To lr
extract = Split(.Cells(i, 1).Value2, "]")
ub = UBound(extract)
If ub > 0 Then
For j = 0 To ub
If Len(extract(j)) > 0 Then
If Left(extract(j), 1) <> "[" Then
found = InStr(1, extract(j), "[")
If found = 0 Then found = Len(extract(j)) + 1
.Cells(nextRow, nextCol).Value2 = Left(extract(j), found - 1)
nextRow = nextRow + 1
If nextRow > lr Then
nextRow = 1
nextCol = nextCol + 1
End If
End If
End If
Next j
End If
Next i
End With
End Sub
Test results:
This is how one of the strings (cell A1) looks like after the split
Edit: measurements for all solutions provided so far:
Timers (with 100,000 rows)
0.824 secs - TextToColumns (0.81054, 0.82812) - Output: same row split to many cols
1.679 secs - Split cells (1.66796, 1.64453) - Output: sequentially by rows, then cols
3.757 secs - ArrayList (3.69140, 3.78125) - Output: sequentially in one column

Answer 2

here's a short and quite fast approach
Sub main()
With Range("A1", Cells(Rows.Count, 1).End(xlUp))
.Replace what:="[*]", replacement:="|", lookat:=xlPart
.TextToColumns DataType:=xlDelimited, Other:=True, OtherChar:="|"
.Columns(1).Delete xlToLeft
End With
End Sub

Answer 3

Here's little different approach using ArrayList
Dim rng As Range
Dim arl As Object
Dim strVal
Dim i As Long
Set arl = CreateObject("System.Collections.ArrayList")
For Each rng In Range("A1:A" & Range("A" & Rows.Count).End(xlUp).Row)
strVal = Split(Replace(rng.Value, "[", "]"), "]")
For i = 2 To UBound(strVal) Step 2
arl.Add CStr(strVal(i))
Next i
Next rng
For i = 0 To arl.Count - 1
Range("B" & i + 1).Value = arl.Item(i)
Next i
Set arl = Nothing