Finding empty cell then loop to get new data - vba

Question

I'm have a spreadsheet that takes 31 different tabs with daily data, then summarizes it into a monthly tab, then converts each day's data into a software upload. In order to expedite my process I'm trying to combine every daily upload into another tab at once instead of copy/pasting each day manually. Currently to see the upload for each day I am changing the number in cell B3 to the day I need and it will give me the upload data.
EDIT:
How I hope this will work is the macro will put "1" in cell B3 on the Upload tab, take the data in A10:I34, paste it over to the first empty cell in column A on the Upload Files tab, then go back to the upload tab, change cell B3 to "2", copy the data in A10:I34, paste it to the next empty cell in column A on the Upload Files tab... repeat until the data from day 31 has been pasted onto the Upload Files tab.
Data is in tab called "Upload"
The only cell that can change on tab "Upload" is cell "B3"
Data range is "A10:I34"
Data needs to paste values on tab "Upload Files"
"Upload Files" has formatting data in row 1 needed for the software
EDIT:
The macro needs to looks for the next empty row after each day's data has been pasted
Loop needs to stop at day 31
My issue now is that I can't get it to go back to the upload tab and change the date to the next day and then continue with the empty cell loop. It ends up just pasting the data over the original data, or not changing the cell value to the next day. Below is what I have for changing the days.
EDIT #3: I tweaked it, it works now. Please take a look and let me know if you think it could be improved. Added For/next.
Dim Count as integer
Dim x as Long
Count = 2
For x = 1 to 30
Do While Worksheets("Upload Files").Range("A" & Count).Value <> ""
Count = Count +1
Loop
Worksheets ("Upload").Range("B3").Value = Worksheets("Upload").Range("B3").Value +1
Worksheets("Upload").Range("A10:I34").Copy
Worksheets("Upload Files").Range("A" & Count).PasteSpecial xl PasteValues
Next x
Any suggestions? Previous attempts just simply selected the exact cell where the previous data ended on the "Upload Files" tab, but adding rows in the "Upload" tab means I have to manually recalculate which cells the data will be pasted, which is about as time consuming as doing the whole thing manually.
Thanks,

Answer 1

I added some comments for your understanding inside the code:
Sub Test1()
Dim Count As Integer
Dim lLastRow As Long
Dim i As Long
Count = 2
' This would give you the last used row in the Sheet
lLastRow = Worksheets("Upload Files").Cells(Worksheets("Upload Files").Rows.Count, 1).End(xlUp).Row
For i = 1 To lLastRow
' You don't specify if you are trying to do anything in this section inside de Loop
' but if you just want to cound for the last row, you can remove the loop.
Next i
If Worksheets("Upload").Range("B3").Value < 32 Then
' Dont need this.
'Worksheets("Upload").Range("B3").Select
Worksheets("Upload").Range("B3").Value = Worksheets("Upload").Range("B3").Value + 1
' Here it would be nice if you specify from what Sheet you are copying this range. I guess is Upload.
Worksheets("Upload").Range("A10:I34").Copy
Worksheets("Upload Files").Range("A" & Count).PasteSpecial xlPasteValues
End If
End Sub

Answer 2

I guess you're after something like follows:
Option Explicit
Sub upload()
Dim targetSht As Worksheet
Set targetSht = Worksheets("Upload Files")
Dim i As Long
With Worksheets("Upload")
For i = 1 To 31
.Range("B3").Value = i
Application.Calculate
With .Range("A10:I34")
targetSht.Cells(targetSht.Rows.Count, 1).End(xlUp).Offset(1).Resize(.Rows.Count, .Columns.Count).Value = .Value
End With
Next
End With
End Sub