Storing only specific values in an array from another array - vba

Question

The goal of this sub is to run through an existing array where all values stored in the array slots before the array slot containing the String "Score" are useless, and all the ones after this slot and before the slot containing the String "Why?" are meaningful. So the array could look like this:
IQRngRef(0).Value2(1) = "Pineapple"
IQRngRef(0).Value2(2) = "Apple"
IQRngRef(0).Value2(3) = "Lemons"
IQRngRef(0).Value2(4) = "Score"
IQRngRef(0).Value2(5) = "23"
IQRngRef(0).Value2(6)= "45"
IQRngRef(0).Value2(7) = "333"
IQRngRef(0).Value2(8) = "Why?"
IQRngRef(0).Value2(9) = "77"
IQRngRef(0).Value2(10) = "60"
I want to then store only the values {23|45|333} into an array roleArray(). The Following is what I came up with, but I'm sure there's an easier/ more efficient way.
Also, this is giving me run-time error 451 property let procedure not defined and property get procedure did not return an object on this line: roleIdentifier = IQRngRef(0).Value2(rowIterator) and I can't figure out how to fix it.
Any help with this would be much appreciated.
Private Sub IdentifyRolesAndScoresRows(ByRef IQRngRef As Variant, ByVal rowNumb As Long)
Dim rowIterator As Long
Dim roleIdentifier As String
Do Until roleIdentifier = "Score"
For rowIterator = 1 To rowNumb
roleIdentifier = IQRngRef(0).Value2(rowIterator)
Next rowIterator
Loop
Dim roleArray(1 To 10) As String
Dim roleArrayCount As Long
Do Until roleIdentifier = "Why?"
For rowIterator = rowIterator + 1 To rowNumb
roleIdentifier = IQRngRef(0).Value2(rowIterator)
roleArrayCount = roleArrayCount + 1
roleArray(roleArrayCount) = roleIdentifier
Next rowIterator
Loop
End Sub
This is the code that fills IQRngRef()
Private Sub CaptureIQRefsLocally(ByVal ShRef As Worksheet, ByVal rowNumb As Long, ByVal colNumb As Long, ByRef IQRef As Variant, ByRef IQRngref As Variant)
'capture IQ references in arrays. Values for column titles in IQRef and full column Ranges in IQRngRef.
Dim iCol As Long
Dim alignIQNumbToArrayNumb As Long
With ShRef
For iCol = 1 To colNumb
alignIQNumbToArrayNumb = iCol - 1
Set IQRngref(alignIQNumbToArrayNumb) = .Range(.Cells(1, iCol), .Cells(rowNumb, iCol))
IQRef(alignIQNumbToArrayNumb) = .Cells(1, iCol).Value
'IsThisaKeyIQ IQRngref, IQRef
Next iCol
End With
End Sub

Answer 1

See if you can adapt this for your particular situation.
Sub x()
Dim v(1 To 10), n1 As Long, n2 As Long, v1, i As Long
v(1) = "Pineapple"
v(2) = "Apple"
v(3) = "Lemons"
v(4) = "Score"
v(5) = "23"
v(6) = "45"
v(7) = "333"
v(8) = "Why?"
v(9) = "77"
v(10) = "60"
n1 = Application.Match("Score", v, 0)
n2 = Application.Match("Why?", v, 0)
v1 = Application.Index(v, Evaluate("ROW(" & n1 + 1 & ":" & n2 - 1 & ")"))
For i = LBound(v1) To UBound(v1)
MsgBox v1(i, 1)
Next i
End Sub

Answer 2

You have to work with "Variant array of 1D Variant arrays" (i.e. Variant/Variant) and then slice these latter by means of Application.Index function as per This Link
so, first change CaptureIQRefsLocally() sub as follows:
Private Sub CaptureIQRefsLocally(ByVal ShRef As Worksheet, ByVal rowNumb As Long, ByVal colNumb As Long, ByRef IQRef As Variant, ByRef IQRngref As Variant)
'capture IQ references in arrays. Values for column titles in IQRef and full column Ranges values in IQRngRef.
Dim iCol As Long
Dim alignIQNumbToArrayNumb As Long
With ShRef
For iCol = 1 To colNumb
alignIQNumbToArrayNumb = iCol - 1
IQRngref(alignIQNumbToArrayNumb) = Application.Transpose(.Range(.Cells(1, iCol), .Cells(rowNumb, iCol)).Value) ' make an 1D array out of range values and store it in current 'IQRngref' element
IQRef(alignIQNumbToArrayNumb) = .Cells(1, iCol).Value
'IsThisaKeyIQ IQRngref, IQRef
Next iCol
End With
End Sub
and then change IdentifyRolesAndScoresRows() sub as follows:
Private Sub IdentifyRolesAndScoresRows(ByRef IQRngref As Variant, ByVal rowNumb As Long)
Dim startIndex As Long, endIndex As Long
startIndex = Application.Match("Score", IQRngref(0), 0)
endIndex = Application.Match("Why?", IQRngref(0), 0)
Dim roleArray As Variant
roleArray = Application.Transpose(Application.Index(IQRngref(0), Evaluate("ROW(" & startIndex + 1 & ":" & endIndex - 1 & ")"))) ' from https://www.mrexcel.com/forum/excel-questions/927644-split-array-vba-2.html
End Sub