How to Pass nested table into sub procedures - sql

Question

In below code am trying to pass nestedTable payment_obj from parent procedure to child procedure, but in child procedure am not able to insert data into nested table as it is throwing even after initialization in parent procedure ERROR- Reference to uninitialized collection"
*Cause: An element or member function of a nested table or varray
was referenced (where an initialized collection is needed)
without the collection having been initialized.
I am collecting data into nested table which need to insert into payment table in child procedure and inserting data into payment table that is collected in nested table in parent procedure. How to achieve this type of requirement if it is not possible with nested table.
CREATE OR REPLACE
PACKAGE pkg_payment
AS
PROCEDURE PROCESS_PAYMENTS;
END pkg_payment;
CREATE OR REPLACE
PACKAGE body pkg_payment
AS
type typ_payment
IS
record
(
payment_id payment1.payment_id%type,
);
type tab_typ_payment
IS
TABLE OF typ_payment;
PROCEDURE prepare_payments(payment_obj OUT tab_typ_payment )
IS
tab_typ_payment_INDEX NUMBER ( 2 ) := 0 ;
BEGIN
payment_obj.extend;
tab_typ_payment_INDEX:= payment_obj.count;
payment_obj ( tab_typ_payment_INDEX ) .payment_id :=tab_typ_payment_INDEX;
END prepare_payments;
PROCEDURE PROCESS_PAYMENTS
IS
payment_obj tab_typ_payment:= tab_typ_payment();
CURSOR C_PUIDS_CUR
IS
(
select puid from payments
);
type PUIDS
IS
TABLE OF C_PUIDS_CUR%rowtype;
PUIDS_OBJ PUIDS := PUIDS();
BEGIN
OPEN C_PUIDS_CUR;
LOOP
FETCH C_PUIDS_CUR bulk collect INTO PUIDS_OBJ limit 100;
BEGIN
FOR I_ROW_PUID IN 1 .. PUIDS_OBJ .count
LOOP
prepare_payments( payment_obj);
END LOOP; -- FOR LOOP
END; -- END for fetch begin
EXIT
WHEN C_PUIDS_CUR %notfound;
END LOOP; -- End for limit loop
CLOSE C_PUIDS_CUR ;
forall i IN 1 .. payment_obj.count SAVE EXCEPTIONS
INSERT INTO payment1 VALUES payment_obj
(i
);
END PROCESS_PAYMENTS;
END pkg_payment;

Answer 1

Procedure prepare_payments needs to initialise payment_obj.
I'm not sure what this is all meant to do, but the following runs without error:
create table payment1 (payment_id number);
create table payments (puid integer);
insert into payments (puid) values (1);
create or replace package pkg_payment
as
procedure process_payments;
end pkg_payment;
/
create or replace package body pkg_payment as
type typ_payment is record
( payment_id payment1.payment_id%type );
type tab_typ_payment is table of typ_payment;
procedure prepare_payments
( payment_obj out tab_typ_payment )
is
tab_typ_payment_index number(2) := 0;
begin
payment_obj := tab_typ_payment(); -- Initialised here
payment_obj.extend;
tab_typ_payment_index := payment_obj.count;
payment_obj(tab_typ_payment_index).payment_id := tab_typ_payment_index;
end prepare_payments;
procedure process_payments is
payment_obj tab_typ_payment := tab_typ_payment();
cursor c_puids_cur is
select puid from payments;
type puids is table of c_puids_cur%rowtype;
puids_obj puids := puids();
begin
open c_puids_cur;
loop
fetch c_puids_cur bulk collect into puids_obj limit 100;
for i_row_puid in 1 .. puids_obj.count loop
prepare_payments(payment_obj);
end loop;
exit when c_puids_cur%notfound;
end loop;
close c_puids_cur;
forall i in 1 .. payment_obj.count save exceptions
insert into payment1 values payment_obj (i);
end process_payments;
end pkg_payment;