Create ComboBox in Excel cells - vba

Question

I want to create a Select or Drop-down List or ComboBox (whatever you want to call it).
I do not want to do it with UserForm because it displays a window on the cells and I want it in the cells. Example (See image)
I want when selecting PERRO in the combobox the cell shows the number 1, if it is GATO the cell shows the number 2, if it is VACA the cell shows the number 3.

Answer 1

You have three options
Use Data Validation (DATA>DATA TOOLS>DATA VALIDATION) as you showed in the image, but you'll have to combine it with VLOOKUP function (kinda painful)
Attach a Combobox Form Control (DEVELOPER>CONTROLS>INSERT) right click and go to format control. From here, you can assign a source list and a result cell in numeric format. I mean if you select Perro, since it is the first element, the result cell give the value 1. It is the best way for me.
Finally, you can use a Combobox ActiveX Control (DEVELOPER>CONTROLS>INSERT), you can add the elements from the properties windows or VBA script by using the method AddItem
For example:
With ComboBox
.AddItem "perro"
.AddItem "gato"
.AddItem "vaca"
.AddItem "cerdo"
End With
and you can create a result cell with a conditional
Select Case Combobox.value
Case "perro": range("a1")=1
Case "gato": range("a1")=2
Case "vaca": range("a1")=3
Case "cerdo": range("a1")=4
End Select
That would be easy for a beginner.

Answer 2

other then the solution by the link provided by QHarr in the comments, you could try a totally VBA solution, with the code making the validation list appear every time the user selects the wanted cell
to do so you have to:
delete and placing back the validation rules at every cell selection
substitute list item select with its index in the list
so you need to deal with both Worksheet_SelectionChange() and Worksheet_Change() event handlers
place the following code in the worksheet code pane
Option Explicit
Dim animals As Variant
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$B$2" Then ' if selected cell is the wanted one (change "$B$2" to any wanted address
Dim element As Variant
Dim position As Long
For Each element In animals 'loop through validation list
position = position + 1 'update index position
If element = Target.Value Then 'if current loop element matches cell content
Application.EnableEvents = False 'prevent subsequent sheet change (deleting and writing cell content) fire this event again and start an infinite loop
Target.Validation.Delete 'remove data validation
Target.Value = position ' write the element index position
Application.EnableEvents = True 'restore proper event handling
Exit For
End If
Next
End If
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Address = "$B$2" Then ' if selected cell is the wanted one (change "$B$2" to any wanted address
With Target
If hasValidation(.Cells) Then
.ClearContents 'clear any previous cell content
Else
animals = Array("Perro", "Gato", "Vaca", "Cerdo") 'set the validation list
.ClearContents 'clear any previous cell content
With .Validation 'set validation rules
.Delete
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:=Join(animals, ",")
.IgnoreBlank = True
.InCellDropdown = True
.InputTitle = ""
.ErrorTitle = ""
.InputMessage = ""
.ErrorMessage = ""
.ShowInput = True
.ShowError = True
End With
End If
End With
End If
End Sub
Function hasValidation(rng As Range) As Boolean
On Error Resume Next
hasValidation = rng.SpecialCells(xlCellTypeSameValidation).Cells.Count = 1
End Function