Avoiding Select in Excel VBA still doesn't speed up my code - vba

Question

This is the first time I couldn't find an answer to my problem on StackExchange. You guys are quite thorough. Anyway, we recently updated to Office 365/Excel 2016 from 2007, and now my VBA scripts won't run, except overnight. I researched and learned that I was a horrible person for using Select/Activate. I have seen the error of my ways, but now even simple code still doesn't want to run on a large sheet. My code, which clears the formatting from the current worksheet to make populating it with data faster:
Sub ClearFormattingAndValidation()
Dim referenceCell As Range
Dim rngToFormat As Range
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
.EnableEvents = False
End With
Set referenceCell = Cells.Find("Some specific text", after:=ActiveCell, LookAt:=xlWhole)
Set rngToFormat = Range(referenceCell.Offset(2, 0), ActiveCell.SpecialCells(xlLastCell))
' rngToFormat.Select
With rngToFormat
.Validation.Delete 'near-instantaneous
.FormatConditions.Delete 'took 7-15 minutes on timed runs
End With
With Application
.ScreenUpdating = True
.Calculation = xlCalculationAutomatic
.EnableEvents = True
End With
End Sub
When I uncomment rngToFormat.Select, I get a total of 76,302 cells, to give you an idea of the size of the spreadsheet. There is a LOT of validation and conditional formatting. In 2007, even using Select/Selection, it ran in seconds. Now, I have no idea how long it takes. I gave up after 5 minutes. It does run successfully on a smaller version of the worksheet.
I would like to avoid removing the validation and conditional formatting if at all possible, but it IS a (time-consuming and costly) possibility for about half of it if that is the only way to speed it up.
Is there anything else that I can do to make the code run faster, or is there something that I'm doing wrong?
Edit: Code changed to reflect comments/suggestions as of 2/21. Similar results.

Answer 1

Your code runs instantly with Excel 2013.
Though the code can be written as below...
Sub ClearFormattingAndValidation()
Dim referenceCell As Range
Dim rngToFormat As Range
With Application
.Calculation = xlCalculationManual
.EnableEvents = False
.ScreenUpdating = False
End With
Set referenceCell = Cells.Find("Some specific text", after:=ActiveCell, LookAt:=xlWhole)
If Not referenceCell Is Nothing Then
Set rngToFormat = Range(referenceCell.Offset(2, 0), ActiveCell.SpecialCells(xlLastCell))
With rngToFormat
.FormatConditions.Delete
.Validation.Delete
End With
End If
With Application
.Calculation = xlCalculationAutomatic
.EnableEvents = True
.ScreenUpdating = True
End With
End Sub

Answer 2

With ActiveSheet
.EnableFormatConditionsCalculation = False
End With
This disables the conditional formatting that is causing the slowdown. It should be reenabled after the code is run.
thanks again, #sktneer. Your help pushed me in the right direction.