Changing target cell on VBA Excel - vba

Question

I'm just trying to figure out if there is a way to change the target cell to run the same code. This code basically opens a directory folder based on the cell A1 but what I want to happen is add a macro button on the same row that uses the value of the cell on that row. (For example, this my code uses the data on A1, I want the code to do that same for A2 if I put the macro button on row 2)
Sub OpenFolder()
Dim MyFolder As String
Dim JobNumber As String
Dim JobYearLeft As String
Dim JobYear As String
Dim FolderNumber As String
Dim i As Integer
Dim FirstFolder As String
JobNumber = Right(Range("A1"), Len(Range("A1")) - 3)
JobYearLeft = Right(Range("A1"), Len(Range("A1")) - 1)
JobYear = Left(JobYearLeft, Len(JobYearLeft) - 4)
i = CInt(JobNumber)
Select Case i
Case 0 To 500
FolderNumber = "0001_0500"
Case 500 To 1000
FolderNumber = "0501_1000"
Case 1000 To 1500
FolderNumber = "1001_1500"
Case 1500 To 2000
FolderNumber = "1501_2000"
End Select
If (JobYear = 17) Then
FirstFolder = "M:\2017\" & FolderNumber & "\" '& Range("A1").Value & "*" & "\"
Else
MyFolder = "M:\2016\" & FolderNumber & "\" '& Range("A1").Value & "*" & "\"
End If
If (JobYear = 17) Then
MyFolder = "M:\2017\" & FolderNumber & "\" & Range("A1").Value & "*" '& "\"
Else
MyFolder = "M:\2016\" & FolderNumber & "\" & Range("A1").Value & "*" '& "\"
End If
MyFolder = Replace(MyFolder, " ", "")
Dim OpenThisFolder As String
Dim GoToFolder As String
MyFolder = Dir(MyFolder, vbDirectory)
GoToFolder = FirstFolder & MyFolder & "\"
GoToFolder = Replace(GoToFolder, " ", "")
ActiveWorkbook.FollowHyperlink GoToFolder
End Sub

Answer 1

You could create few Subs (one for each button) that would call your Main Sub (that's the code that you posted) and pass to it variable containing your cell variable. Like this:
Sub ButtonForRow1()
MainSub "A1"
End Sub
Sub ButtonForRow2()
MainSub "A2"
End Sub
Sub MainSub(TargetCell as String)
(...)
JobNumber = Right(Range(TargetCell), Len(Range(TargetCell)) - 3)
(...)
End Sub
Hope this helps!

Answer 2

As commented, you can try something like this. Here are the things you need?
Form Button named Button 1 (or any other name you want just make sure you assign it correctly in below code).
Code to position your button every time you select a cell and then assign the action it will execute when clicked. Below code that goes in the Sheet Module (Sheet where you process your data) will do just that.
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
On Error GoTo sureexit
Dim myButton As Shape, myAction As String
Application.EnableEvents = False
Set myButton = Me.Shapes("Button 1") '/* used a form control button */
If Not Intersect(Target, Me.Range("B1:B10")) Is Nothing Then
'/* target cell is on B1:B10, to get A1:A10 offset by -1 */
myAction = "'OpenFolder(Evaluate(""" & _
Target.Offset(, -1).Address & """))'"
'/* move the button to the selected cell */
With myButton
.Top = Target.Top
.Height = Target.Height
.Left = Target.Left
.Width = Target.Width
.OnAction = myAction
.TextFrame.Characters.Text = "Follow"
.Visible = msoCTrue
End With
Else
'/* hide button if selected cell is not between B1:B10 */
myButton.Visible = msoFalse
End If
sureexit:
Application.EnableEvents = True
End Sub
Of course you need a procedure in the regular module that you will assign in your Button 1 on the fly. Below is a simple procedure which expects 1 range argument.
Sub OpenFolder(r As Range)
MsgBox r.Address & ": " & r.Value2
End Sub
You can incorporate this with your procedure changing all Range("A1") with the variable r which is passed every time the button is clicked. Hope this gets you going.