Giving equations specific numbers - vba

Question

I'm new to VBA and I really would appreciate the help. First I should mention that I use OFFICE 2016.
I used Macro recording to create a macro that copies the selected equation then it inserts a table (one row,two columns)and adjust it to remove borders. After that the macro pastes the copied equation in the first cell and moves to the next cell and insert an empty equation (which the user then inserts the desired number of the equation in it).
It works fine except until it reaches the step where it should paste the copied equation. Every time I run the macro I get
Run-time error: 6335
and the macro breaks and when I debug it, this is the line that breaks the procedure:
Selection.PasteAndFormat (wdFormatOriginalFormatting)
after debugging when I hit the continue/run button, it completes the job as required.
Below is the macro I use. Thanks in advance.
Sub MacroEQNUMBER()
'
' MacroEQNUMBER Macro
'
'
Dim rng As Range
If Selection.Range = "" Then
Selection.HomeKey Unit:=wdLine
Selection.EndKey Unit:=wdLine, Extend:=wdExtend
End If
Set rng = Selection.Range
rng.Cut
ActiveDocument.Tables.Add Range:=Selection.Range, NumRows:=1, NumColumns:= _
2, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:= _
wdAutoFitFixed
With Selection.Tables(1)
If .Style <> "Table Grid" Then
.Style = "Table Grid"
End If
.ApplyStyleHeadingRows = True
.ApplyStyleLastRow = False
.ApplyStyleFirstColumn = True
.ApplyStyleLastColumn = False
.ApplyStyleRowBands = True
.ApplyStyleColumnBands = False
.Borders.Enable = False
End With
Selection.Tables(1).Cell(1, 1).Range.Select
Selection.TypeText Text:="["
Selection.OMaths.Add Range:=Selection.Range
Selection.MoveRight Unit:=wdCharacter, Count:=2
Selection.MoveLeft Unit:=wdCharacter, Count:=1
Selection.TypeText Text:="]"
Selection.MoveLeft Unit:=wdCharacter, Count:=2
Selection.Tables(1).Columns(1).Cells.Width = 80
Selection.Tables(1).Columns(2).Cells.Width = 350
Selection.Tables(1).Cell(1, 2).Range.Select
Selection.PasteAndFormat (wdFormatOriginalFormatting)
Selection.TypeBackspace
Selection.HomeKey Unit:=wdLine
Selection.MoveLeft Unit:=wdCharacter, Count:=4
End Sub

Answer 1

I get the feeling the problem comes from pasting the equation. Since you're using Selection it's quite possible you're putting the Selection in a table cell structure. Word used to allow this, which would "break" the document. In more recent versions it's simply not allowed, which will result in an error...
Rather than try to put bandaids on your recorded code, I've done my best to interpret what is meant (thank you for the excellent description) and convert it to "object code". The SELECTION object isn't ideal because you can never be sure where it is, nor what is meant. Better is to use the underlying object model, usually RANGE objects.
To begin, the Selection is assigned to a Range - now, no matter where the visible selection is in the document, the Range will never change.
Next, I assign the new table to a Table object. From that, I can get the Range of the first cell and work with it (insert text).
I apparently do need a Selection for inserting the OMath, so I position between the square brackets, select and insert that. Finally, the columns are formatted, the cut equation pasted and the selection positioned at the beginning of the first cell (I think that's what you wanted, but I'm not sure about this last).
Sub MacroEQNUMBER()
'
' MacroEQNUMBER Macro
'
'
Dim rng As Range
Dim tbl As word.Table
Dim cel As word.Cell
Dim rngCell As word.Range
If Selection.Range = "" Then
Selection.HomeKey Unit:=wdLine
Selection.EndKey Unit:=wdLine, Extend:=wdExtend
End If
Set rng = Selection.Range
rng.Cut
Set tbl = ActiveDocument.Tables.Add(Range:=Selection.Range, NumRows:=1, NumColumns:= _
2, DefaultTableBehavior:=wdWord9TableBehavior, AutoFitBehavior:= _
wdAutoFitFixed)
With tbl
If .Style <> "Table Grid" Then
.Style = "Table Grid"
End If
.ApplyStyleHeadingRows = True
.ApplyStyleLastRow = False
.ApplyStyleFirstColumn = True
.ApplyStyleLastColumn = False
.ApplyStyleRowBands = True
.ApplyStyleColumnBands = False
.Borders.Enable = False
End With
Set cel = tbl.Cell(1, 1)
Set rngCell = cel.Range
rngCell.Text = "[]"
rngCell.Collapse wdCollapseStart
rngCell.MoveStart wdCharacter, 1
rngCell.Select
rngCell.OMaths.Add Range:=rngCell
tbl.Columns(1).Cells.width = 80
tbl.Columns(2).Cells.width = 350
Set rngCell = tbl.Cell(1, 2).Range
rngCell.PasteAndFormat wdFormatOriginalFormatting
rngCell.Characters(rngCell.Characters.Count - 1).Delete
tbl.Cell(1, 1).Select
Selection.Collapse wdCollapseStart
End Sub