Clicking on a link without Id or class - vba

Question

I have a code that does a research for the user in a website and then get the information from that research.
In the process of acessing the information, I need to click o a link inside the website. This link can change everytime the user makes a different research, so I can't use it's href to acess it. I have no clue about what to do.
Here's my code until now: it goes until the webpage where the link is.
Steps of the code:
user insert his research. example: "icms base de calculo pis cofins"
open ie in: http://www.stj.jus.br/SCON/
insert the research
click on: "sumulas", "decisões monocromaticas" and "informativos de jurisprudencia". That way I acess only the "acordãos".
click on "pesquisar"
I need to click on the link in front of "Acórdãos"
Here's the code:
Sub teses2()
Dim pesquisa As String
Dim ie As InternetExplorer
Dim elemns As Object
Dim elem As Object
Dim elemns2 As Object
Dim elem2 As Object
Dim elem3 As Object
Dim obj As Object
pesquisa = InputBox("Digite os termos que quer pesquisar: ", "", "")
Set ie = New InternetExplorer
ie.Visible = True
ie.navigate "http://www.stj.jus.br/SCON/"
Application.Wait (Now + TimeSerial(0, 0, 20))
ie.document.getElementById("pesquisaLivre").innerText = pesquisa
Set elemns2 = ie.document.getElementsByTagName("input")
For Each elem2 In elemns2
If elem2.Value = "SUMU" Then
elem2.Click
End If
If elem2.Value = "DTXT" Then
elem2.Click
End If
If elem2.Value = "INFJ" Then
elem2.Click
End If
Next
Set elemns = ie.document.getElementsByTagName("input")
For Each elem In elemns
If elem.Value = "Pesquisar" Then
elem.Click
End If
Next
End Sub

Answer 1

I have revisited this and made it tighter.
Option Explicit
Sub teses2()
Dim pesquisa As String
Dim ie As InternetExplorer
'*SUSPENDED * pesquisa = InputBox("Digite os termos que quer pesquisar: ", "", "")
pesquisa = "icms base de calculo pis cofins"
Set ie = New InternetExplorer
ie.Visible = True
ie.navigate "http://www.stj.jus.br/SCON/"
While ie.Busy
DoEvents
Wend
While ie.Document.ReadyState = "complete"
DoEvents
Wend
'Stop
Application.Wait (Now + TimeSerial(0, 0, 3))
ie.Document.getElementById("pesquisaLivre").innerText = pesquisa
Dim oHtml As MSHTML.HTMLDocument '* gives intellisense
Set oHtml = ie.Document
Dim oSelectors As MSHTML.IHTMLDOMChildrenCollection
Set oSelectors = oHtml.querySelectorAll("div.blocoCampos input")
Dim lSelectorResultList As Long
lSelectorResultList = oSelectors.Length
Dim lSelectorResultLoop As Long
For lSelectorResultLoop = 0 To lSelectorResultList - 1
Dim objInputCheckbox As Object
Set objInputCheckbox = oSelectors.Item(lSelectorResultLoop)
If Not objInputCheckbox Is Nothing Then
Dim sLabel As String
sLabel = objInputCheckbox.Value
If VBA.InStr(1, "|SUMU|DTXT|INFJ|", "|" & sLabel & "|", vbTextCompare) > 0 Then
objInputCheckbox.Click
End If
End If
Next
'* release references
Set objInputCheckbox = Nothing
Set oSelectors = Nothing
Set oHtml = Nothing
Dim elemns As MSHTML.IHTMLDOMChildrenCollection
'Set elemns = ie.Document.getElementsByTagName("input")
Set oHtml = ie.Document
Set elemns = oHtml.querySelectorAll("div#botoesPesquisa input:nth-child(1)")
Debug.Assert elemns.Length = 1
Dim elem As Object
Set elem = elemns.Item(0)
'For Each elem In elemns
If elem.Value = "Pesquisar" Then
elem.Click
End If
'Next
'* release references
Set elem = Nothing
Set elemns = Nothing
While ie.Busy
DoEvents
Wend
'While ie.Document.ReadyState = "complete"
' DoEvents
'Wend
'* POST NAVIGATION
'Stop
Application.Wait (Now + TimeSerial(0, 0, 10))
Set oHtml = ie.Document
Dim objResultList As MSHTML.IHTMLDOMChildrenCollection
Set objResultList = oHtml.querySelectorAll("div#itemlistaresultados span:nth-child(2) a")
Dim lResultCount As Long
lResultCount = objResultList.Length
Debug.Print
Dim lResultLoop As Long
For lResultLoop = 0 To lResultCount - 1
Dim anchorLoop As MSHTML.HTMLAnchorElement
Set anchorLoop = objResultList.Item(lResultLoop)
Debug.Print anchorLoop.href
Next
ie.Quit
Set ie = Nothing
'Stop
End Sub