Range.FindNext causing a runtime error 91 - vba

Question

I am using VBA to search a 15x15 array for the location (row and column number) of all the '1's and map them to a new location.
Sub findvalues()
Dim OldRow As Long
Dim OldColumn As Long
With Worksheets(1).Range("a1:o15")
Set c = .Find(1, LookIn:=xlValues)
If Not c Is Nothing Then
firstAddress = c.Address
Do
cellAddress = c.Address
OldRow = Range(cellAddress).Row
OldCol = Range(cellAddress).Column
MsgBox (OldRow)
With Worksheets(1).Range("r3:r16")
Set oldmapping = .Find(OldRow, LookIn:=xlValues, LookAt:=xlWhole)
NewCol = oldmapping.Offset(, 1).Value
MsgBox (NewCol)
End With
Set c = .FindNext(c)
MsgBox (c.Address)
Loop While Not c Is Nothing And c.Address <> firstAddress
End If
End With
End Sub
The strange thing is, the code runs fine until the fourth loop where it gets to MsgBox (c.Address) and throws a
runtime error 91 - object variable not set
I have a feeling it is down to the Set c = .FindNext(c) on the line previous but can't figure out why as it works fine for the first 3 loops.

Answer 1

The .FindNext derived from,
Set c = .Find(1, LookIn:=xlValues)
... is being superseded by the intermediate,
Set oldmapping = .Find(OldRow, LookIn:=xlValues, LookAt:=xlWhole)
Your .FindNext and loop conditions are no longer valid.
Switch to an alternate method for the second .Find.
Option Explicit
Sub findvalues()
Dim OldRow As Long, OldCol As Long, NewCol As Long
Dim oldmapping As Variant, c As Range, firstAddress As String, cellAddress As String
With Worksheets(1).Range("a1:o15")
Set c = .Find(1, LookIn:=xlValues)
If Not c Is Nothing Then
firstAddress = c.Address
Do
cellAddress = c.Address
OldRow = Range(cellAddress).Row
OldCol = Range(cellAddress).Column
MsgBox (OldRow)
oldmapping = Application.Match(OldRow, Worksheets(1).Range("r3:r16"), 0)
If Not IsError(oldmapping) Then
NewCol = Worksheets(1).Range("r3:r16").Cells(oldmapping).Offset(, 1).Value
MsgBox NewCol
End If
Set c = .FindNext(c)
MsgBox (c.Address)
Loop While Not c Is Nothing And c.Address <> firstAddress
End If
End With
End Sub

Answer 2

A loop while (or do while) will still run once when the test is true, here is a simple example:
Sub temp()
Dim X As Long
X = 0
Do
X = X + 1
Debug.Print X
Loop While X < 5
End Sub
Notice 5 shows up in the list of values in your debug window.
A simple test should fix this up for you.
If Not c Is Nothing then MsgBox (c.Address)
or you could tell it to exit the loop if c is nothing, your choice