AMPL syntax error offset 1067 - ampl

Question

I have a syntax error in my code,is there someone who can help me?
set surgery;
set OOR;
set OR{surgery};
set surgeon ordered;
set aa{surgeon};
param S>0;
param time{i in surgery}>=0;
#param aa{i in surgery}>=0;#病人对应的医生
var st{i in surgery,m in OR[i]}>=0;
var et{i in surgery,m in OR[i]}>=0;
var x{i in surgery,m in OR[i]} integer binary;
#var y{i in surgery,a in stage, b in stage:a<>b} binary;
var z{c in surgeon,k in aa[c],l in aa[c],m in OR[k],n in OR[l]:k>l or k<l} binary;
var n{i in surgery,k in surgery,m in OR[i] inter OR[k]:k>i or k<i} binary;
var C;
minimize t:C;
subject to seven{i in surgery,m in OR[i]}:
st[i,m]+time[i]*x[i,m]<=C;#目标
subject to choose{i in surgery}:
sum{m in OR[i]}x[i,m]=1;#至少选择一个
subject to time2{i in surgery,j in OR[i]}:
et[i,j]=st[i,j]+time[i]*x[i,j];#et计算公式
subject to OR1{i in surgery,k in surgery,m in OR[i] inter OR[k]:k>i}:
et[i,m]-st[k,m]<=S*n[i,k,m];
subject to OR2{i in surgery,k in surgery,m in OR[i] inter OR[k]:k>i}:
et[k,m]-st[i,m]<=S*(1-n[i,k,m]);
subject to doctor1{c in surgeon,k in aa[c],l in aa[c],m in OR[k],n in OR[l]:k>l}:
et[l,n]-st[k,m]<=S*z[c,k,l,m,n];
subject to doctor2{c in surgeon,k in aa[c],l in aa[c],m in OR[k],n in OR[l]:k>l}:
et[k,m]-st[l,n]<=S*(1-z[c,k,l,m,n]);
the above is my code and i got a message that:
4.mod, line 37 (offset 1067):
syntax error
and the line 37 is: subject to doctor1{c in surgeon,k in aa[c],l in aa[c],m in OR[k],n in OR[l]:k>l}:
who can tell the reason? thank you so much !

Answer 1

You have already defined n as an indexed variable on line 15 of the program. Now you're referring to n within your constraint definition. I'm guessing it's not supposed to be the same "n" as the one you created as a variable. In any case, you're not allowed to use a variable within the indexing of a constraint like this, so AMPL gives an error message.
The AMPL "syntax error" messages are not very helpful in figuring out the cause of problems like this. One thing that gave me a clue was that even though the "m in OR[k]" part has exactly the same format as "l in OR[l]" and appears before it, that one doesn't trigger an error message.
{c in surgeon,k in aa[c],**m in OR[k]**,l in aa[c],**n in OR[l]**: k>l}
I tried swapping the k & m terms with the l & n terms:
{c in surgeon,l in aa[c],n in OR[l],k in aa[c],m in OR[k]: k>l}
and the error was still associated with "n in OR[l]". This made it pretty clear that there was something special about either n or l, so I went looking elsewhere in the program and noticed that you'd already declared n.
(BTW, this is a good reason to use meaningful variable names rather than just calling things "n" and "aa"...)