Do not Delete worksheets if it is in array - vba

Question

Dim L As Double
Dim Workings() As Variant
Workings = Array("Due SO not Billed", "Working Paper", "Ageing Over 14 Days")
On Error Resume Next
Application.DisplayAlerts = False
For L = 1 To Worksheets.Count
If Worksheets(L).Name <> Workings Then
Worksheets(L).Delete
Exit For
End If
Next L
Application.DisplayAlerts = True
On Error GoTo 0
I tried writing above code. The purpose is I have 10 worksheets in a workbook but final output requires only 3 sheets and I want to delete the rest of the worksheets. I tried above code with array and whatever name I gave in the array should be saved and all other remaining sheets should be be deleted. I'm getting type mismatch error. Can someone help please?

Answer 1

Use Match to test whether the worksheet's Name is in the array:
Dim Workings() As Variant
Dim ws As Worksheet
Workings = Array("Due SO not Billed", "Working Paper", "Ageing Over 14 Days")
Application.DisplayAlerts = False
For Each ws In Worksheets
If IsError(Application.Match(ws.Name, Workings, False)) Then
ws.Delete
End If
Next
Application.DisplayAlerts = True

Answer 2

Smells like homework. It's not working because the Workings variable is an array while the other is a string, they are different types. To test if a string is inside an array do
If Not IsInArray(Worksheets(L).Name, Workings)
Function IsInArray(stringToBeFound As String, arr As Variant) As Boolean
IsInArray = (UBound(Filter(arr, stringToBeFound)) > -1)
End Function

Answer 3

Using VBA Filter function gives you the added benefit of comparing Text. In this way you do not have to be concerned with capitalization.
Sub DeleteWorksheets()
Dim Workings() As Variant
Dim ws As Worksheet
Workings = Array("Due SO not Billed", "Working Paper", "Ageing Over 14 Days")
Application.DisplayAlerts = False
For Each ws In Worksheets
If UBound(Filter(Workings, ws.Name, True, vbTextCompare)) = -1 Then ws.Delete
Next
Application.DisplayAlerts = True
End Sub

Answer 4

This is my valueInArray function:
Public Function valueInArray(myValue As Variant, myArray As Variant) As Boolean
Dim cnt As Long
For cnt = LBound(myArray) To UBound(myArray)
If CStr(myValue) = CStr(myArray(cnt)) Then
valueInArray = True
Exit Function
End If
Next cnt
End Function
It is quite a lot of code and it loops, but it works. Plus, it works ok for both integers and strings.