Extract file names from directory into textbox Powerpoint VBA - vba

Question

For school I am creating numerous PowerPoint presentations with pictures (hundreds to thousands) arranged such that it creates a "flashcard" like experience. I have written a code to import photos from a directory and insert the pictures separately in successive slides with the name of that picture at the bottom of the slide in the textbox. I've had no issues with that so far. However, I want to create an index page that lists all the file names, in order, but a separate lines in a textbox at the beginning of my presentation.
I included just the relevant portion of my code.
' (2a)Adds Index Page, compiles file names into index page as a list
' Creates slide
Set oSld = ActivePresentation.Slides.Add(ActivePresentation.Slides.Count + 1, ppLayoutBlank)
With Application.ActivePresentation.PageSetup
.SlideHeight = 612
.SlideWidth = 1087
End With
' Create Title Box with Specified Dimensions and Slide Position
Set oPic = oSld.Shapes.AddShape(Type:=msoShapeRectangle, _
Left:=40, Top:=36, Width:=1007, Height:=540)
' FORMAT TEXTBOX SHAPE
' Shape Name
oPic.Name = "Index"
' No Shape Border
oPic.Line.Visible = msoFalse
' Shape Fill Color
oPic.Fill.ForeColor.RGB = RGB(255, 255, 255)
' Shape Text Color
oPic.TextFrame.TextRange.Font.Color.RGB = RGB(1, 0, 0)
' Left Align Text
oPic.TextFrame.TextRange.Paragraphs.ParagraphFormat.Alignment = ppAlignLeft
' Vertically Align Text to Top
oPic.TextFrame2.VerticalAnchor = msoAnchorTop
' Adjust Font Size
oPic.TextFrame2.TextRange.Font.Size = 11
' Adjust Font Style
oPic.TextFrame2.TextRange.Font.Name = "Arial"
' Change file path to desired directory and add "\" TO THE END:
strPath = "C:\Users\josephandrews\Desktop\Test\" '*****N.B. note the last "\" at end of line
strFileSpec = "*.jpg" 'you can change the selected file format, (e.g. "*.png") but only one file type can be used
strTemp = Dir(strPath & strFileSpec)
' Text inside Shape. Important to note that strTemp is the pic file name
oPic.TextFrame.TextRange.Characters.Text = strTemp & vbNewLine
' Required paramater for Loop through pictures
Do While strTemp <> ""
' Causes search for next picture in directory
strTemp = Dir
Loop
I expected this to create a list of all the file names in a text box.
It is only showing the name of the first file with a new line afterwards.

Answer 1

Found the answer. Here is my example.
Sub Test_2()
' Demonstrates the use of DIR to return a file at a time
Dim strPath As String
Dim strFile As String
Dim strFileSpec As String
Dim strFilesFound As String
Dim oSld As Slide
Dim oTbox As Shape
strPath = "C:\Users\BobComputer\Desktop\Test\" ' or wherever you want to look for files
strFileSpec = "*.jpg" ' or whatever type of files you want to list
' get the first file that meets our specification
strFile = Dir$(strPath & strFileSpec)
' if we got at least one file, continue:
While strFile <> ""
strFilesFound = strFilesFound & strFile & vbCrLf
' get the next file and loop
strFile = Dir
Wend
' let's see what we've got
'MsgBox strFilesFound
Set oSld = ActivePresentation.Slides(2)
Set oTbox = oSld.Shapes(1)
oTbox.TextFrame.TextRange.Characters.Text = strFilesFound
End Sub