Ticket printing - vb.net

Question

I'm busy to write ticket program in Vb , everything is working perfectly
but when i'm printing things goes wrong,
the ticket is printing correctly ( in this example 3 ) the ticketnumbers are overlapping
example : 3 tickets 15200 , 15201 , 15203
3 tickets are printed but the 1520 is printed correct but on evey ticket the 1,2 a 3 are printed over each other
What the hell is going wrong ??
this is a part of the code
Private Sub PrintDocument1_PrintPage(sender As System.Object, e As System.Drawing.Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
Dim AZ As String
Dim x As Integer
Dim LB1, LB2 As Integer
AZ = TextBox12.Text
For x = 0 To AZ - 1
LB1 = Val(TextBox1.Text) + x
e.Graphics.DrawString(LB1, New Font("Microsoft Sans Serif", 10), Brushes.Black, New Point(155, 265))
next
end sub

Answer 1

Sorry, I misread and gave you the wrong answer.
One way I've done this in the past was to call the printdocument.print inside a loop. The only problem with this is that you get a messagebox telling you that each page is printing so that may not be ideal.
Anyway, here is a method that you might be able to work off with. It's been a while since I've used the printdocument as I find the ReportViewer/Report is easier to work with.
'Widen the scope of LB1 so it can be used in both methods
Dim LB1, LB2 As Integer 'Declared outside of any methods (Class Level)
Private Sub PrintDocument1_PrintPage(sender As Object, e As Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
e.Graphics.DrawString(LB1.ToString, New Font("microsoft sans serif", 10), Brushes.Black, New Point(155, 265))
End Sub
Private Sub btnPrint_Click(sender As Object, e As EventArgs) Handles btnPrint.Click
Dim AZ As Integer = CInt(NumericUpDown1.Value)
For x = 0 To AZ - 1
'We can get rid of this if we use a NumericUpDown control and set it
'to ensure we are working with a number.
If Not Integer.TryParse(TextBox1.Text, LB1) Then
'notify the user with maybe a messagebox that the input is invalid
Exit Sub
End If
LB1 += x
PrintDocument1.Print()
Next
End Sub
Again, I've not worked with this for a while but I seem to remember e.HasMorePages being a way of telling the PrintDocument to move to the next page. You might google up on it and see if it's a better alternative than looping and displaying the Print messagebox for each page like this code is doing. Hopefully it's at least gives you something to work off of.
EDIT --- THIS IS THE PROPER WAY OF DOING WHAT YOU'RE WANTING TO DO ---
I decided to go ahead and look into the HasMorePages myself and It would be the better and more proper solution. You would need to change a few things but here is an example of your code using it.
Dim LB1, LB2 As Integer 'Declared outside of any methods
Dim currentTicket = 0
Private Sub PrintDocument1_PrintPage(sender As Object, e As Printing.PrintPageEventArgs) Handles PrintDocument1.PrintPage
'how many tickets to print
Dim TotalTickets As Integer = CInt(NumericUpDown1.Value)
'build the current ticket number (I would look at my previous code
'which uses TryParse instead of Val as an invalid input could cause
'your application to fail)
LB1 = Val(TextBox1.Text) + currentTicket
'Print the ticket number on the page
e.Graphics.DrawString(LB1.ToString, New Font("microsoft sans serif", 10), Brushes.Black, New Point(155, 265))
'increase the currentTicket counter
currentTicket += 1
'did we go over the total number of tickets we want to print
If currentTicket < TotalTickets Then
'if not, we need to tell the printdocument that we have more to print
e.HasMorePages = True
End If
'otherwise, we'll stop there and print the pages we produced.
End Sub
This will give you the single dialog that shows how many pages are being printed instead of a single dialog per page.