VBA: Using the DateAdd Function - vba

Question

I have a spreadsheet of with identical rows repeated in sequences of three. For example below A represents a row of information. In column S are dates. I'd like to change the date in column S in the second row of each sequence to one month after the original date and the third row of each sequence to two months after the original date and do continue this for the entire spreadsheet using a loop and the DateAdd function.
Here is the code I have now, but the I'm getting a compile error on the DateAdd function (this is my first time using it):
Sub DateChange()
Dim r As Long
Application.ScreenUpdating = False
For r = Range("A" & Rows.Count).End(xlUp).Row To 1 Step -1
With Cells(r, 1).EntireRow
.Copy
.Resize(2).Offset(1, 0).Insert Shift:=xlDown
End With
Cells(r + 1, "S").Value = DateAdd("m", 1, Cells(r, "S"))
Cells(r + 2, "S").Value = DateAdd("m", 2, Cells(r, "S"))
Next r
Application.ScreenUpdating = True
End Sub

Answer 1

If you experience difficulties using the DataAdd function then you can bypass it like this:
Option Explicit
Sub DateChange()
Dim r As Long
Dim dttTemp As Date
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1")
Application.ScreenUpdating = False
For r = ws.Range("A" & ws.Rows.Count).End(xlUp).Row To 1 Step -1
With ws.Cells(r, 1).EntireRow
.Copy
.Resize(2).Offset(1, 0).Insert Shift:=xlDown
End With
dttTemp = ws.Cells(r, "S").Value
ws.Cells(r + 1, "S").Value = DateSerial(Year(dttTemp), Month(dttTemp) + 1, Day(dttTemp))
ws.Cells(r + 2, "S").Value = DateSerial(Year(dttTemp), Month(dttTemp) + 2, Day(dttTemp))
Next r
Application.ScreenUpdating = True
End Sub
Note, that I am also fully qualifying all references (for good coding practice and to avoid errors). This means I am referring to ThisWorkbook.Worksheets("Sheet1").Cells(r, "S").Value instead of just Cells(r, "S") (as you did). Like this VBA knows in which Excel file to look and at which sheet to look at when searching for cell S3 (for example). Also, I am telling VBA that I am interested in that cell's .Value and not .Value2 or .Formula or anything else.
Let me know if the above helped.