finding variables in textboxes - vba

Question

I have an issue when using textboxes that contains variables in word2016.
I would like to preform a search for a variable that may exist within textbox's text, and during certain instances I would like to replace it with a new variable. An example textbox is shown below :
I want to search for the DOCPROPERTY "Checked By". This DOCPROPERTY does not exist in the textbox but the text "Checked By" does , but my code as attached below finds it regardless. Since it is not a DOCPROPERTY, it should not return true.
' ************************************************************
' ********* finding docproperties in text, headers and textboxes
' **************************************************************
Public Function findProperty(doc As Document, findText As String) As Boolean
Dim rngStory As word.Range
Dim oFld As word.Field
Dim objShape As Shape
Dim temp As String
Dim temp2() As String
Dim element As Variant
ActiveWindow.View.ShowFieldCodes = True
If findText = "_DocumentTitle" Then
findProperty = True
Exit Function
End If
findProperty = False
For Each objShape In ActiveDocument.Shapes
If objShape.Type = msoTextBox Then
'do the required action
temp2 = Split(objShape.TextFrame.TextRange.Text, "DOCPROPERTY")
For Each element In temp2
temp = replace(element, "DOCPROPERTY", "")
temp = replace(temp, "\* MERGEFORMAT", "")
temp = replace(temp, """", "")
If InStr(UCase(temp), Trim(UCase(findText))) > 0 Then
findProperty = True
Exit Function
End If
Next
End If
Next objShape
For Each rngStory In doc.StoryRanges
Do
For Each oFld In rngStory.Fields
'If oFld.Type = wdFieldDocProperty Then
'Dig a little deeper and see what the field code contains.
'Formatting of property is a pain....
temp = replace(oFld.Code.Text, "DOCPROPERTY", "")
temp = replace(temp, "\* MERGEFORMAT", "")
temp = replace(temp, """", "")
If Trim(UCase(temp)) = Trim(UCase(findText)) Then
findProperty = True
Exit Function
End If
Next oFld
Set rngStory = rngStory.NextStoryRange
Loop Until rngStory Is Nothing
Next rngStory
ActiveWindow.View.ShowFieldCodes = False
End Function

Answer 1

You're splitting a string into an array using "DOCPROPERTY" as the delimiter, so there is no need to replace "DOCPROPERTY" with vbNullString, ("").
temp2 = Split(objShape.TextFrame.TextRange.Text, "DOCPROPERTY")
For Each element In temp2
temp = replace(element, "DOCPROPERTY", "")
I think that you can test the size of temp2, if it is bigger than 0 then there was a "DOCPROPERTY" found, if it is 0 then there was no "DOCPROPERTY" found.
if UBound(temp2) > 0 then findProperty = True
But probably a better way is to look at Field(n).code which returns the field code text and then you know exactly what you have...

Answer 2

With the suggestion from #SlowLearner is the working code presented below.
Public Function findProperty(doc As Document, findText As String) As Boolean
Dim rngStory As word.Range
Dim oFld As word.Field
Dim objShape As Shape
Dim element As Variant
findProperty = False 'default false
'**************************************************************************************
'**************** ALL DOCUMENTS NEED A TITLE EVEN IF ITS NOT IN USE *******************
'**************************************************************************************
If findText = "_DocumentTitle" Then
findProperty = True
Exit Function
End If
For Each objShape In ActiveDocument.Shapes
If objShape.Type = msoTextBox Then
'do the required action
For Each element In objShape.TextFrame.TextRange.Fields
If InStr(UCase(element.Code.Text), Trim(UCase(findText))) > 0 Then
findProperty = True
Exit Function
End If
Next element
End If
Next objShape
For Each rngStory In doc.StoryRanges
Do
For Each oFld In rngStory.Fields
'Dig a little deeper and see what the field code contains.
If InStr(UCase(oFld.Code.Text), Trim(UCase(findText))) > 0 Then
findProperty = True
Exit Function
End If
Next oFld
Set rngStory = rngStory.NextStoryRange
Loop Until rngStory Is Nothing
Next rngStory
End Function