VBA error caused by iterating past expected stopping point - vba

Question

Background:
I am attempting to convert an old style of managing departments, facilities, and job titles at work to a new more convenient lookup table style format. Right now each set of data for new departments, facilities, and job titles are stored on separate sheets (a couple per week) and the sheet name is a date.
The issue:
The program runs fine for the majority of the workbook; however, I eventually get a
1004 - Application-defined or objected-defined error
When debugging, I find that my row value has to 1,048,577 and therefore caused the error. I am unsure how the iterating value is escaping my handling of it.
The code:
Sub cleanUp()
Dim wks As Worksheet
Dim wksNum As Long
Dim destWks As Worksheet
Dim rng As Range
Dim row As Long
Dim col As Long
Dim destRow As Long
Dim lastRow As Long
Dim itemType As String
Set destWks = ActiveWorkbook.Sheets("new")
destRow = 2
For wksNum = 1 To ActiveWorkbook.Sheets.Count
NextWks:
Set wks = ActiveWorkbook.Worksheets(wksNum)
If wks.Name = "new" Then
wksNum = wksNum + 1
GoTo NextWks
End If
lastRow = wks.Cells(wks.Rows.Count, 1).End(xlUp).row
For row = 1 To lastRow
NextRow:
Select Case wks.Cells(row, 1).Value
Case "New Hospitals"
itemType = "Hospital"
row = row + 1
GoTo NextRow
Case "New Departments"
itemType = "Department"
row = row + 1
GoTo NextRow
Case "New Job Titles"
itemType = "Job Title"
row = row + 1
GoTo NextRow
Case "none"
row = row + 1
GoTo NextRow
Case ""
row = row + 1
GoTo NextRow
End Select
destWks.Cells(destRow, 1).Value = wks.Name
destWks.Cells(destRow, 2).Value = itemType
wks.Range("A" & row & ":C" & row).Copy destWks.Range("C" & destRow)
destRow = destRow + 1
Next row
Next wksNum
End Sub
Example Sheet:
New Hospitals
None
New Departments
10 146 7205-DeptA
10 193 9178-DeptB
New Job Titles
004315 JobTitleA
A side question:
Is there a more elegant way of skipping to the next iteration of a for loop without using a GoTo statement. My thoughts are that these are causing my issue.
Thank you for any and all help.

Answer 1

The problem is if your data on any sheet ends with either of the group headings or none then it will start an eternal loop adding 1 to row until it reaches a row number that is not supported by the worksheet.
You have taken the loop outside the For Loop and so it does not stop.
It is better to test for the opposite and do the code instead of using the archaic Goto.
Use this:
Sub cleanUp()
Dim wks As Worksheet
Dim wksNum As Long
Dim destWks As Worksheet
Dim rng As Range
Dim row As Long
Dim col As Long
Dim destRow As Long
Dim lastRow As Long
Dim itemType As String
Set destWks = ActiveWorkbook.Sheets("new")
destRow = 2
For wksNum = 1 To ActiveWorkbook.Sheets.Count
Set wks = ActiveWorkbook.Worksheets(wksNum)
If wks.Name <> "new" Then
lastRow = wks.Cells(wks.Rows.Count, 1).End(xlUp).row
For row = 1 To lastRow
Select Case wks.Cells(row, 1).Value
Case "New Hospitals", "New Departments", "New Job Titles"
itemType = Replace(wks.Cells(row, 1).Value, "New ", "")
Case "None", ""
Case Else
destWks.Cells(destRow, 1).Value = wks.Name
destWks.Cells(destRow, 2).Value = itemType
wks.Range("A" & row & ":C" & row).Copy destWks.Range("C" & destRow)
destRow = destRow + 1
End Select
Next row
End If
Next wksNum
End Sub
Edited to simplify Select Case based on Scott Holtzman's now deleted answer
Output with provided data: