VBA: make calculation - output just value - vba

Question

I am very new with VBA and I was hoping someone could help me. I would like to create a macro that makes a calculation but returns just the value. I have two specific examples where I would like to do this:
-One is where the macro calculates the average of A2:A100 and return the Value of that average in B100, then the average between A3:A101 and return the value in B101, and so in until B700
-The second case is where the macro finds cell containing the Max value in cells A2:A101, and return that value in cell E1.
Thanks for the help.

Answer 1

You need User defined Functions instead of Subs.
Then in the needed cell (say, B100) you enter =MyFunc(A2:A100).
In your case, it seems you can copy-paste down.
The assignment could be done at the VBA level also, with Range("B100").Formula = MyFunc(...
This, with a little googling, should quickly get you going.
Among many references out there:
https://support.office.com/en-us/article/Create-custom-functions-in-Excel-2f06c10b-3622-40d6-a1b2-b6748ae8231f

Answer 2

You have two options for doing any sort of calculation (which I assume is going to be more involved than replicating the built-in functionality of AVERAGE(), SUM() or MAX()).
User Defined Function (UDF) - Create a Function that returns a single value (like Double, String or Variant array). This function can take numeric or range arguments, and optionally it can reference values from the active worksheet and returns the calculated value of the cell it was invoked from. Here are two examples:
Manual Calculation - Create a Subroutine that reads values and/or files and manually updates the values of cells before it exits. This method is required when more than one cell needs to written. It also requires a trigger, such as a button to press, or a menu item to click, or some other event to call the subroutine. There is two ways to process a table of cells. One is direct using the .Cell() method, and the other is the faster one taking all the values into an array and writing out all the values with one command.
Example UDF Code (in a Module)
'---------------------------------------------------------------------------------------
' Procedure : MySquare
' Author : ja72
' Date : 10/29/2017
' Purpose : Returns `x^2/c` where c is defined in cell [B2]
'---------------------------------------------------------------------------------------
'
Public Function MySquare(ByVal x As Double) As Double
Dim c As Double
c = [B2]
' Same as: c = ActiveSheet.Range("B2").Value
MySquare = x ^ 2 / c
End Function
'---------------------------------------------------------------------------------------
' Procedure : MyAverage
' Author : ja72
' Date : 10/29/2017
' Purpose : Uses the built-in funcrtion 'Average()` on the input cells
'---------------------------------------------------------------------------------------
'
Public Function MyAverage(ByVal r As Range) As Double
MyAverage = WorksheetFunction.Average(r)
End Function
Example worksheet layout
Example Manual Calculations (in a Sheet)
'---------------------------------------------------------------------------------------
' Procedure : FillMultiplicationTableDirect
' Author : John
' Date : 10/29/2017
' Purpose : Fills a n×n table of cells directly
'---------------------------------------------------------------------------------------
'
Public Sub FillMultiplicationTableDirect(ByVal n As Long)
Dim r_table As Range
' Start from top left cell B15
Set r_table = Range("B15")
' Process the cells one by one
Dim i As Long, j As Long
For i = 1 To n
For j = 1 To n
' Write the resuling cell directly
r_table.Cells(i, j).Value = i * j
Next j
Next i
End Sub
'---------------------------------------------------------------------------------------
' Procedure : FillMultiplicationTableOffline
' Author : John
' Date : 10/29/2017
' Purpose : Fills a n×n table of cells with an array
'---------------------------------------------------------------------------------------
'
Public Sub FillMultiplicationTableOffline(ByVal n As Long)
Dim r_table As Range
' Start from top left cell B15 and grab n×n cells
Set r_table = Range("B15").Resize(n, n)
' Define an array with the values
Dim res() As Variant
' Fill the array with the existing values of the cells
res = r_table.Value
'Process the array (offline calculation)
Dim i As Long, j As Long
For i = 1 To n
For j = 1 To n
res(i, j) = i * j
Next j
Next i
' Write the array back to the worksheet
r_table.Value = res
End Sub
The above functions need to be triggered manually with a command like
Call Sheet1.FillMultiplicationTableDirect(10)
or
Call Sheet1.FillMultiplicationTableOffline(10)
Example Result