Verify SQL Query completed MS Excel VBA - sql

Question

In my workbook I have 3 SQL-database queries which are triggered using a
'Initiate datbase querying
ThisWorkbook.RefreshAll
In my DB_Connection worksheet I added the following code to verify if the query ran successfully or failed (to be used in a log-sheet later on). If there are no more queries running, the macro continues with the next phase.
Private Sub QueryTable_AfterRefresh(Success As Boolean)
Dim Succeeded As Integer
Dim Failed As Integer
Succeeded = 0
Failed = 0
If Success Then
Succeeded = Succeeded + 1
Worksheets("DB_Connection").Range("L2").Value = Succeeded
Else
Failed = Failed + 1
Worksheets("DB_Connection").Range("M2").Value = Failed
End If
End Sub
However, the QueryTable_AfterRefresh is never called. I placed a stop to identify if it is being called or not.
Any suggestions?

Answer 1

You can't just type out an event handler signature and expect it to work. If you navigate to that QueryTable_AfterRefresh procedure, you should notice the contents of the code pane drop-downs - the only way a handler procedure named QueryTable_AfterRefresh could exist and work, is if you have a Private WithEvents QueryTable As QueryTable declaration:
Notice the left-hand dropdown says QueryTable (the name of the WithEvents field) and the right-hand dropdown says AfterRefresh (the name of the event).
If what you have is this (General) on the left and QueryTable_AfterRefresh on the right:
...then what you're looking at is essentially dead code that nothing will ever invoke, at least not through QueryTable events.
Declare a module-level WithEvents variable, select it from the left-hand dropdown, then select the AfterRefresh event in the right-hand dropdown; the VBE will generate the correct method signature for that event on that object.
Then you need to Set that object reference before you do ThisWorkbook.RefreshAll. You could do that in the Workbook_Open handler, however with the field being Private you won't be able to access it from the ThisWorkbook module. One solution is to make it Public, a better solution is to expose a method to properly initialize it:
Option Explicit
Private WithEvents QueryTable As QueryTable
Public Sub Initialize()
Set QueryTable = Me.QueryTables(1)
End Sub
Private Sub QueryTable_AfterRefresh(ByVal Success As Boolean)
'...
End Sub
And then give that worksheet a compile-time code name (set its (Name) property in the properties toolwindow) and call that method from Workbook_Open in ThisWorkbook - for example if the sheet has QuerySheet for a code name, you can invoke it like this (note there's no need to dereference that object from the ThisWorkbook.Worksheets collection):
Option Explicit
Private Sub Workbook_Open()
QuerySheet.Initialize
End Sub