Storing Variables from userforms VBA - vba

Question

I would like to save the ComboBox1 & ComboBox2 values as variables which I could use in the module I return to once the Userform is correctly completed by the user however I am unsure how to do this.
Option Explicit
Private isCancelled As Boolean
Public Property Get Cancelled() As Boolean
Cancelled = isCancelled
End Property
Private Sub CancelButton1_Click()
isCancelled = True
Me.Hide
End Sub
Public Property Get Benefit() As String
Benefit = IIf(Me.ComboBox1.ListIndex = -1, vbNullString, Me.ComboBox1.Text)
End Property
Public Property Get Costdelivery() As String
Costdelivery = IIf(Me.ComboBox2.ListIndex = -1, vbNullString, Me.ComboBox2.Text)
End Property
Private Sub ComboBox1_Change()
ValidateForm
End Sub
Private Sub ComboBox2_Change()
ValidateForm
End Sub
Private Sub ValidateForm()
Me.Okbutton1.Enabled = (Benefit <> vbNullString And Costdelivery <> vbNullString)
End Sub
Private Sub UserForm_Activate()
ValidateForm
End Sub
Private Sub UserForm_Initialize()
'populate "Combo-Box with Boards
With Me.ComboBox1
.Clear ' clear previous items (not to have "doubles")
.AddItem "Very High"
.AddItem "High"
.AddItem "Medium"
.AddItem "Low"
End With
With Me.ComboBox2
.Clear ' clear previous items (not to have "doubles")
.AddItem "Very High"
.AddItem "High"
.AddItem "Medium"
.AddItem "Low"
End With
End Sub
Private Sub Okbutton1_Click()
Dim Ben As Long
Ben = Me.ComboBox1.Value ***ERROR
Dim Cost As Long
Cost = Me.ComboBox2.Value **** ERROR
Me.Hide
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then
Cancel = True
isCancelled = True
Me.Hide
End If
End Sub
Ideally I would like to store the Low,Medium,High or Very high as values 9,10,11,12 as I will be using these as cell references in the module I return to after the userform is closed.
I understand I would need to state a public property my attempt which does not work is below;
Public Function ConfidenceChart()
Dim ben As Long, costd As Long
ben = UserForm4.ComboBox1.Text
If ben = "Low" Then ben = 9
If ben = "Medium" Then ben = 8
If ben = "High" Then ben = 7
If ben = "Very High" Then ben = 6
costd = UserForm4.ComboBox2.Text
If costd = "Low" Then costd = 12
If costd = "Medium" Then costd = 13
If costd = "High" Then costd = 14
If costd = "Very High" Then costd = 15
End Function

Answer 1

Excel controls allow you to link controls to cells. In this way, you can store the values of the controls for later use.
Userform controls use the ControlSource property to establish this link. In my Demo below I create two named ranges on a setting page (named after the controls' names for easy reference) and set the controls ControlSource property to the named range.
Addendum
#Mat'sMug pointed out that the OP needed to store a value from a lookup list base on the selection from a ComboBox. This can also be achieved using named ranges.
Private Sub UserForm_Initialize()
'populate "Combo-Box with Boards
With Me.ComboBox1
.RowSource = "List1"
.ColumnCount = 2
.ColumnWidths = "0 pt;49.95 pt"
End With
With Me.ComboBox2
.RowSource = "List2"
.ColumnCount = 2
.ColumnWidths = "0 pt;49.95 pt"
End With
End Sub
You will need to change some of the properties of the ComboBoxes.
Private Sub UserForm_Initialize()
'populate "Combo-Box with Boards
With Me.ComboBox1
.RowSource = "List1"
.ColumnCount = 2
.ColumnWidths = "0 pt;49.95 pt"
.ControlSource = "ComboBox1"
End With
With Me.ComboBox2
.RowSource = "List2"
.ColumnCount = 2
.ColumnWidths = "0 pt;49.95 pt"
.ControlSource = "ComboBox2"
End With
End Sub

Answer 2

Ben and Cost are locals, they're only visible from within the Click handler.
It's not the forms' job to know where these values need to end up - the form is only there to collect user input.
You already have Benefit and CostDelivery properties that the caller is able to access.
Use them!
With New UserForm1 'whatever the name of that form is
.Show
If Not .Cancelled Then
Sheet1.Range("A1").Value = .Benefits
Sheet1.Range("B1").Value = .CostDelivery
End If
End With
If you need them to be numeric values, then you're not populating your comboboxes correctly.
Nowhere you're mapping "Very High" to 12, the comboboxes only know about the strings.
To do that you need to change this:
With Me.ComboBox1
.Clear ' clear previous items (not to have "doubles")
.AddItem "Very High"
.AddItem "High"
.AddItem "Medium"
.AddItem "Low"
End With
And assign Me.ComboBox1.List to a 2D array. Or a Range, if you have one that looks like this:
A B
15 Very High
14 High
13 Medium
12 Low
You could have a this helper method:
Private Sub PopulateFromRange(ByVal control As MSForms.ComboBox, ByVal source As Range, Optional ByVal valueColumn As Long = 1, Optional ByVal hasHeader As Boolean = True)
With control
.ColumnCount = source.Columns.Count
.ColumnWidths = GetColumnWidths(source)
.ListWidth = IIf(control.Width > source.Width, control.Width, source.Width)
.List = source.Range(source.Rows(IIf(hasHeader, 2, 1)).EntireRow, source.Rows(source.Rows.Count).EntireRow).Value
.BoundColumn = valueColumn
End With
End Sub
Private Function GetColumnWidths(ByVal source As Range) As String
Dim cols As Long
cols = source.Columns.Count
Dim widths()
ReDim widths(1 To cols)
Dim col As Long
For col = 1 To cols
widths(col) = source(, col).Width
Next
GetColumnWidths = Join(widths, ",")
End Function
(taken from this post specifically about populating combobox and listbox controls from ranges)
And populate your comboboxes like this:
PopulateFromRange Me.ComboBox1, DataSheet.Range("A1:B5")
PopulateFromRange Me.ComboBox2, DataSheet.Range("D1:E5")
Assuming you have a DataSheet worksheet with ranges [A1:B5] and [D1:E5] respectively containing the text and corresponding numeric value for each item.