Updating integer values with a integer variable in MS Access using Delphi 10 - sql

Question

iexc := round(iexc/icount);
iint := round(iint/icount);
inau := round(inau/icount);
iovr := round(iovr/icount);
adoquery1.SQL.Text := 'update Tickets_Tbl set Excitment = iexc where
RollerCoaster = "'+sride+'"';
adoquery1.ExecSQL;
adoquery1.SQL.Text := 'update Tickets_Tbl set Intensity = iint where
RollerCoaster = "'+sride+'"';
adoquery1.ExecSQL;
adoquery1.SQL.Text := 'update Tickets_Tbl set Nausea = inau where
RollerCoaster = "'+sride+'"';
adoquery1.ExecSQL;
adoquery1.SQL.Text := 'update Tickets_Tbl set Overall = iovr where
RollerCoaster = "'+sride+'"';
adoquery1.ExecSQL;
The main problem is that when I run the code it keeps saying that there is no default value for field begin updated. Please help.

Answer 1

The problem is that you're hard-coding the variable names within your SQL instead of setting the values properly (which should be done using a parameterized query, BTW). Also, your SQL is horrific; you can do this in a single UPDATE instead of repeating it multiple times.
This should get you started (see note below about the #13):
iexc := round(iexc/icount);
iint := round(iint/icount);
inau := round(inau/icount);
iovr := round(iovr/icount);
AdoQuery1.SQL.Text := 'update Tickets_Tbl'#13 +
'set Excitement = :iexc,'#13 +
' Intensity = :iint,'#13 +
' Nausea = :inau,'#13 +
' Overall = :iovr'#13 +
'where RollerCoaster = :sride';
AdoQuery1.Parameters.ParamByName('iexc').Value := iexc;
AdoQuery1.Parameters.ParamByName('iint').Value := iint;
AdoQuery1.Parameters.ParamByName('inau').Value := inau;
AdoQuery1.Parameters.ParamByName('iovr').Value := iovr;
AdoQuery1.Parameters.ParamByName('sride').Value := sride;
AdoQuery1.ExecSQL;
The #13 in the code is a carriage return, which simply makes it easier because you don't have to worry about properly inserting spaces before or after the end or start of each successive line. It's basically the same as typing the query into SQL Server Management Studio line-by-line, pressing Enter at the end of each line. You can do the same thing using AdoQuery1.SQL.Add for each line, but to me that makes it harder when you need to copy the SQL out and clean it up to run externally for testing or debugging or modification. The above is similar to
AdoQuery1.SQL.Clear;
AdoQuery1.SQL.Add('update Tickets_Tbl');
AdoQuery1.SQL.Add('set Excitement = :iexc,');
AdoQuery1.SQL.Add('Intensity = :iint,');
AdoQuery1.SQL.Add('Nausea = :inau,');
AdoQuery1.SQL.Add('Overall = :iovr');
AdoQuery1.SQL.Add('where RollerCoaster = :sride');
Use whichever one is easier and more readable for you personally. I use the first, because I have a utility that will take plain SQL from the clipboard and format it with the ' and #13 + automatically for pasting into Delphi's Code Editor, or take that quoted text containing embedded '' characters and #13 + and remove them automatically to allow pasting into SSMS or Access or another SQL utility without manual cleanup.