Find and replace multiple values in Excel using VBA - vba

Question

I'm looking for VBA code to run in Excel to find and replace lots of words.
Basically, it will be a simple Excel file where Sheet1 contains phrases in 1 column which contains names to be replaced (not the whole phrase but one name which might consist of few words). Second sheet2 contains in 1 column values which I need to find in Sheet1 (there might be more than one time when value appears to be found in 1st column) and column which contains translation. I don't need Google API for this because names are very custom.
I came across to the following script but it does nothing basically.
Sub ReplaceValues()
Dim dataSht As Worksheet
Dim editSht As Worksheet
Dim dataRange As Range
Dim dataColumn As Long
Dim editColumn As Long
Dim dataEndRow As Long
Dim editEndRow As Long
'sheet that holds all the values we want to find
Set dataSht = Sheet2
'sheet we want to edit
Set editSht = Sheet1
Dim replaceValue As String
'replace value is empty string
replaceValue = ""
'set the column of the data sheet to A
dataColumn = 1
'set the colmun of the sheet to edit to A
editColumn = 5
dataEndRow = dataSht.Cells(dataSht.Rows.count, dataColumn).End(xlUp).Row
editEndRow = editSht.Cells(editSht.Rows.count, editColumn).End(xlUp).Row
'this is the range of the data that we're looking for
Set dataRange = dataSht.Range(dataSht.Cells(1, dataColumn),
dataSht.Cells(dataEndRow, dataColumn))
Dim count As Long
Dim val As String
For i = 1 To editEndRow
val = editSht.Cells(i, editColumn).Value
count = Application.WorksheetFunction.CountIf(dataRange, val)
If count > 0 And Trim(val) <> "" Then
editSht.Cells(i, editColumn).Value = replaceValue
End If
Next i
End Sub

Answer 1

Finally, I was able to do what I need with a very simple piece of code. Get trained folks!
Sub Test()
Dim Sh1 As Worksheet
Dim Sh2 As Worksheet
Dim FndList, x&
Set Sh1 = Sheets(1)
Set Sh2 = Sheets(2)
FndList = Sh2.Cells(1, 1).CurrentRegion
For x = 1 To UBound(FndList)
Sh1.Cells.Replace What:=FndList(x, 1), Replacement:=FndList(x, 2), LookAt:=xlPart
Next
End Sub

Answer 2

So as I understand correctly you want a list of phrases translated by a dictionary - word by word. The following script should do it - assuming Sheet1 contains the phrases (in column 1 from row 2) and Sheet2 contains the dictionary(column1 for original values, column2 for translations and also from row2 on). The replaced/translated phrases will appear in column2 of Sheet1.
Firstly, in your original code, vba will take Sheet1 and Sheet2 as two undefined variable automatically, hence there's no alert about this. You should use Worksheets() collection to specify the worksheet.
Secondly, you forgot to change the value of replaceValue. Actually, you can put the cell.value into the replace function as a parameter directly. Therefore there is no need to set a variable for this unless you want to make it more readable.
Lastly, if you want to check whether a word is contained or not. Use InStr function. However in your case, using a replace function is good enough. It will replace the word into the translation you wanted, and will do nothing if there is no match to be found.
Sub btn_Click()
Dim cntPhrases As Integer
Dim cntDict As Integer
Worksheets("Sheet1").Activate
cntPhrases = Worksheets("Sheet1").Range("A:A").Cells.SpecialCells(xlCellTypeConstants).Count - 1
cntDict = Worksheets("Sheet2").Range("A:A").Cells.SpecialCells(xlCellTypeConstants).Count - 1
MsgBox (cntPhrases)
Dim i As Integer
Dim j As Integer
Dim phrase As String
Dim org As String
Dim rep As String
For i = 2 To cntPhrases + 1
phrase = Cells(i, 1)
For j = 2 To cntDict + 1
org = Worksheets("Sheet2").Cells(j, 1)
rep = Worksheets("Sheet2").Cells(j, 2)
phrase = replace(phrase, org, rep)
Next j
Cells(i, 2) = phrase
Next i
End Sub

Answer 3

You could also do it like this.
Sub main()
Dim Find_text() As String
Dim Replace_text() As String
Dim str As String
str = "test 150 test 160 test 170 test 200 test 220"
Find_text = Split("150 160 170 180 190 200 210 220")
Replace_text = Split("15 16 17 18 19 20 21 22")
For i = 0 To UBound(Find_text)
For j = 0 To UBound(Replace_text)
If InStr(str, Find_text(j)) > 0 Then
str = Replace(str, Find_text(j), Replace_text(j))
End If
Next
Next
MsgBox str
End Sub