Variable that automatically updates when another property is updated - vb.net

Question

I'm sure this is a very simple thing and there's just something I fundamentally don't understand about properties/variables. I want the class to have a variable that is assigned/calculated after some property values are input. This isn't homework, I'm just using a simplified example.
Public Class person
Public Property name As String
Public Property address As String
Public phoneNumber As String
Public Sub getPhoneNumber()
phoneNumber = lookLookThemUpInThePhoneBook
End Sub
End Class
I might not know the person's name AND address when they are created, but as soon as they are both assigned, I want the phone number to be calculated.
I know I could just do
Dim Eddy As New person
Eddy.name = "Ed Wood"
Eddy.address = "123 Sample Road"
Eddy.getPhoneNumber()
Debug.Print(Eddy.phoneNumber)
But this will get very cumbersome having to manually run the procedure, so I figure there has to be a way to have that value get proactively assigned.
I'd like to be able to do this
Eddy.name = "Ed Wood"
Eddy.address = "123 Sample Road"
Debug.Print(Eddy.phoneNumber) ' His phone number is just automatically looked up.

Answer 1

You can delay the phone number lookup until the phoneNumber property is referenced by implementing that logic in the setter of that property (as mentioned in the comments). Here is an example of that:
Public ReadOnly Property phoneNumber As String
Get
'Leverage a class level private variable and wrap in an
'If Statement if you only want To look it up once.
Return lookLookThemUpInThePhoneBook()
End Get
End Property
Then when you do objYourPerson.phoneNumber it does the look up for you.

Answer 2

Both the Name and Address properties can try to set the phone number when they are modified
Public Class Person
Private _name As String = ""
Private _address As String = ""
Private _phoneNumber As String = "not set yet..."
Public Property Name As String
Get
Return _name
End Get
Set(value As String)
_name = value
setPhoneNumber()
End Set
End Property
Public Property Address As String
Get
Return _address
End Get
Set(value As String)
_address = value
setPhoneNumber()
End Set
End Property
Public Property PhoneNumber As String
Get
Return _phoneNumber
End Get
Private Set(value As String)
_phoneNumber = value
End Set
End Property
Public Sub setPhoneNumber()
If Name <> "" AndAlso Address <> "" Then PhoneNumber = lookThemUpInThePhoneBook(Name, Address)
End Sub
Private Function lookThemUpInThePhoneBook(name As String, address As String) As String
Return "123456789" ' search by name and address here
End Function
End Class
usage:
Sub Main()
Dim Eddy As New Person()
Eddy.Name = "Ed Wood"
Console.WriteLine(Eddy.PhoneNumber)
Eddy.Address = "123 Sample Road"
Console.WriteLine(Eddy.PhoneNumber)
Console.ReadLine()
End Sub
output
not set yet...
123456789

Answer 3

something like this...
Public Class Person
Public Sub New(strname As String, straddress As String)
name = strname
address = straddress
_phoneNumber = LookThemUpInThePhoneBook(strname, straddress)
End Sub
Private Function LookThemUpInThePhoneBook(pName As String, pAddress As String) As String
Dim myPhone As String = ""
'Do work to look up phone number
Return myPhone
End Function
Private _phoneNumber As String
Public ReadOnly Property phoneNumber As String
Get
Return _phoneNumber
End Get
End Property
Private _name As String
Public Property name As String
Get
Return _name
End Get
Set(value As String)
_name = value
End Set
End Property
Private _address As String
Public Property address As String
Get
Return _address
End Get
Set(value As String)
_address = value
End Set
End Property
End Class
Then
Dim Eddy As New Person("Eddy wood", "123 Sample Road")
Debug.Print(Eddy.phoneNumber)