Arguments passed to WorkerScript source - qml

Question

I need to load documents which filepath is provided by a FileDialog. The document are rather long to load so I want to display a BusyIndicator while loading the docs. In order to get the UI spinned while loading my doc I need to load my docs in a WorkerScript. Now I need to provide my filepath to the functions in the .js file pointed by WorkerScript::source. I could not find any way to do so.
Any idea?
Here is my source code:
WorkerScript
{
id: importScanWorkerScript
source: "script.js"
}
FileDialog
{
id: importScanDialog
visible: false
title: "Import a [scan] file"
folder: "/home/arennuit/Desktop/living_room_traj0n_scannedScene"
nameFilters: [ "STL files (*stl)" ]
selectedNameFilter: "STL files (*stl)"
onAccepted:
{
importScanDialog.visible = false;
busyIndicator.running = true;
uiController.onImportScanDevMenuClicked(importScanDialog.fileUrl);
busyIndicator.running = false;
}
}
BusyIndicator
{
id: busyIndicator
running: false
anchors.centerIn: parent
}

Answer 1

WorkerScript allows you to send custom object to a thread and also to get a custom object back, I guess the documentation is pretty clear. So the answer to your question is WorkerScript.sendMessage(). In the simple example below the WorkerScript receives random number of iterations from main.qml and so generates and sent back generated text, displayed by main.qml. The GUI doesn't freeze while waiting:
main.qml
import QtQuick 2.9
import QtQuick.Window 2.0
import QtQuick.Controls 2.2
Window {
id: window
width: 600
height: 400
visible: true
ScrollView {
id: view
anchors.fill: parent
clip: true
TextArea {
id: myText
text: ""
enabled: false
}
}
Component.onCompleted: {
var cnt = 1000 + Math.round(Math.random() * 1000);
myText.text = "Please wait, generating text (" + cnt + " characters) ...";
myWorker.sendMessage({count: cnt});
}
WorkerScript {
id: myWorker
source: "script.js"
onMessage: {
myText.text = messageObject.reply;
myText.enabled = true;
spinner.running = false;
}
}
BusyIndicator {
id: spinner
anchors.centerIn: parent
running: true
}
}
script.js
function pause(millis)
{
var date = new Date();
var curDate = null;
do {
curDate = new Date();
} while((curDate - date) < millis);
}
WorkerScript.onMessage = function(message) {
var txt = "";
var count = message.count;
for(var i = 0;i < count;i ++)
{
var ch = 97 + Math.round(Math.random() * 25);
txt += String.fromCharCode(ch);
var eol = Math.round(Math.random() * 30);
if(eol === 1)
txt += "\r\n";
else if(!(eol % 5))
txt += " ";
pause(10);
}
WorkerScript.sendMessage({ 'reply': txt })
}