Excel VBA: replace entire cell with value - vba

Question

Can you help me with loop that will go through cells A3:A50 and replace entire cell with a new value.
Reference below:
[ita-IT] to IT
[jpn] to JA
[por-BR] to PTBR
[spa-ES] to ES
etc.
Thanks for tips!

Answer 1

Try:
Sub ReplaceValues()
Dim r As Range
Dim v() As Variant
Dim i As Integer
v = [{"ita-IT","IT";"jpn","JA";"por-BR","PTBR";"spa-ES","ES"}]
Set r = ActiveSheet.Range("A3:A50")
For i = LBound(v) To UBound(v)
r.Replace what:=v(i, 1), replacement:=v(i, 2), lookat:=xlWhole, MatchCase:=False
Next i
End Sub
Edit:
There's no problem having 50 (or more) replacement pairs, but this would be much easier to manage by storing them in a table in the workbook, rather than listing them in a VBA array:
You can replace cell contents which have text before / after your lookup value by using wildcards. So combining those changes, your code now becomes:
Sub ReplaceValues2()
Dim r As Range
Dim v() As Variant
Dim i As Integer
v = Sheet1.ListObjects("tbReplacement").DataBodyRange
Set r = ActiveSheet.Range("A3:A50")
For i = LBound(v) To UBound(v)
r.Replace What:="*" & v(i, 1) & "*", Replacement:=v(i, 2), LookAt:=xlWhole, MatchCase:=False
Next i
End Sub

Answer 2

Here is an approach. If you get a lot of codes to replace it could look like spaghetti, and if there is a logic to the replacement, it would be nice to build in the logic, but it does what you asked, and is, I hope, readable.
Sub ReplaceStrings()
Dim result As String
For Each myCell In Range("A3:A50")
Select Case myCell.Value
Case "[ita-IT]"
result = "IT"
Case "[jpn]"
result = "JA"
Case "[por-BR]"
result = "PTBR"
Case "[spa-ES]"
result = "ES"
Case Else
result = myCell.Value
End Select
myCell.Value = result
Next myCell
End Sub
EDIT - To go with the original spirit but to meet the requirement of matching within the string, I replaced Case with an If Elseif series and used Like and wildcards to match. Note To match square brackets (assuming that was what you meant), I had to enclose them in square brackets. I also amended to reference the ActiveSheet to be safe, drawing on the other answer (which I am not criticizing, just showing another way to think about it).
Sub ReplaceStrings()
Dim result, s As String
For Each myCell In ActiveSheet.Range("A3:A50")
s = myCell.Value
If s Like ("*[[]ita-IT[]]*") Then
result = "IT"
ElseIf s Like "*[[]jpn[]]*" Then
result = "JA"
ElseIf s Like "*[[]por-BR[]]*" Then
result = "PTBR"
ElseIf s Like "*[[]spa-ES[]]*" Then
result = "ES"
Else
result = s
End If
myCell.Value = result
Next myCell
End Sub