Arrange columns based on the order of values in an array - and buttons disappearing - vba

Question

I have this code which is looking in a column (On a different sheet at XFD1) and creating an array from the values in that column. Then it is searching for those values one at a time across a row on the current sheet. When it finds a match, it cuts the column and inserts it at the location that corresponds to the order of the values in the array.
I'm not getting any compile errors. I placed a button (not ActiveX) on the worksheet and used it to execute the code. Here is what I see:
Nothing appears to happen. Columns are not moved at all.
The computer is obviously "thinking " because the whirly-gig is spinning away.
And here is the Mysterious part - The button disappears! it never comes back. I placed several buttons on the worksheet and tried them all. The button disappears every time.
I really need to get this working. All I want is to reorder the columns to the same order as my list on the other sheet (95 items in the list). I thought this code would do it but I seem to have entered the Twilight Zone and things are not as they seem (at least from my perspective)!
Here it is:
Sub Reorder_Columns()
Dim arrColumnOrder(1 To 95) As String
Dim index As Integer
Dim Found As range
Dim tick As Integer
For index = 1 To 95
arrColumnOrder(index) = UserFormDropDownDataSheet.range("XFD1")
Next index
Application.ScreenUpdating = False
tick = 1
For index = LBound(arrColumnOrder) To UBound(arrColumnOrder)
Set Found = Rows("1:1").Find(arrColumnOrder(index), LookIn:=xlValues, LookAt:=xlWhole, _
SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False)
If Not Found Is Nothing Then
If Found.column <> tick Then
Found.EntireColumn.Cut
Columns(tick).Insert Shift:=xlToRight
Application.CutCopyMode = False
End If
tick = tick + 1
End If
Next index
Application.ScreenUpdating = True
End Sub

Answer 1

The answer to the question concerning what was wrong with my original code is:
First, I was trying to set the size of the array but should have been working with a dynamic array as I expect the data in my array column will grow as I add more columns to the sheet I am trying to sort. So, Dim arrColumnOrder(1 To 95) As String should have been Dim arrColumnOrder As Variant.
I was then trying to iterate over my array with
For index = 1 To 95
arrColumnOrder(index) = UserFormDropDownDataSheet.range("XFD1")
Next index
Which of course is all wrong. I replaced this with
arrColumnOrder = UserFormDropDownDataSheet.range("XFD1:XFD95").Value
Then, in
Set Found = Rows("1:1").Find(arrColumnOrder(index), LookIn:=xlValues, LookAt:=xlWhole, _
SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False)
Should have been "... Find (arrColumnOrder(index, 1)..."
The answer to why the button was moving is that I did not Set the format option of the button (right click the button, Format Control>Properties>Select "Don't move or size with cells.") So when things were moving (and weirdly because my code was all wrong) The button moved with the cell when the column was copied and pasted.
Here is my final code and it works and does exactly what it is expected to do. Namely, it creates an array from the data in the range "XFD1:XFD95" (on a separate worksheet where I have the column headers stored in the proper order), then it sorts the columns in the active worksheet to match the order of the array. I did not want to explicitly call a sheet name as this will run on varying sheets. Using Find as opposed to Match, works just fine for me as this is not a huge amount of data I'm dealing with so speed is not an issue.
Sub Reorder_Columns()
Dim arrColumnOrder As Variant
Dim index As Interger
Dim Found As range
Dim tick As Integer
arrColumnOrder = UserFormDropDownDataSheet.range("XFD1:XFD95").Value
Application.ScreenUpdating = False
tick = 1
For index = LBound(arrColumnOrder) To UBound(arrColumnOrder)
Set Found = Rows("1:1").Find(arrColumnOrder(index, 1), LookIn:=xlValues, LookAt:=xlWhole, _
SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False)
If Not Found Is Nothing Then
If Found.column <> tick Then
Found.EntireColumn.Cut
Columns(tick).Insert Shift:=xlToRight
Application.CutCopyMode = False
End If
tick = tick + 1
End If
Next index
Application.ScreenUpdating = True
End Sub
For me, one of the big lessons here is to not try to write code when I have only slept for two hours! I was really tired and making silly mistakes because I was not thinking clearly. I got a good night's rest and then this morning I was easily able to see where I went wrong.