changing vb.net chart xAxis maximum and minimum datetime type - vb.net

Question

I am using chart control on vb.net windows form application.
I am loading data into chart1 and all looks good; I am using this data type:
Chart1.Series("test").XValueType = DataVisualization.Charting.ChartValueType.DateTime
Chart1.Series("test").YValueType = DataVisualization.Charting.ChartValueType.Int32
Then I am using a Trackbar1 control to change/zoom/rescale xAxis and using this code:
Private Sub TrackBar1_Scroll(sender As Object, e As EventArgs) Handles TrackBar1.Scroll
ChartRanger(TrackBar1.Value)
End Sub
Having TrackBar1 min=0 and max=366 in Property window.
While the ChartRanger function looks like this:
Private Sub ChartRanger(theDays As Integer)
Chart1.ChartAreas(0).AxisX.IntervalType = 0
Chart1.ChartAreas(0).AxisX.Interval = 0
Chart1.ChartAreas(0).AxisX.Minimum = 0
Chart1.ChartAreas(0).AxisX.Maximum = theDays
End Sub
There is no debugging error and it looks like working; but the logic is not correct in the output.
i.e. What I am trying to achieve is to let app user define minimum datetime and maximum datetime for chart1 xAxis. having dataset contains a daily records.
Update: I have seen the other related posts, they suggest answers for ASP, VBA but can't find answer for VB.Net win forms; its more for the best logic here.

Answer 1

I think your problem is Chart1.ChartAreas(0).AxisX.Maximum = theDays. The AxisX type is a Double representing a DateTime, while theDays is an Integer. You need to figure out what the maximum date for AxisX should be based on the value of theDays, and convert that date to a double using ToOADate().
Here's a working example:
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Chart1.Series.Clear()
Dim s = Chart1.Series.Add("s")
s.ChartType = DataVisualization.Charting.SeriesChartType.Point
s.XValueType = DataVisualization.Charting.ChartValueType.DateTime
s.XValueType = DataVisualization.Charting.ChartValueType.Int32
For i As Integer = 0 To 100
s.Points.AddXY(Date.Today.AddDays(i), i)
Next
TrackBar1.Maximum = 100
End Sub
Private Sub TrackBar1_Scroll(sender As Object, e As EventArgs) Handles TrackBar1.Scroll
Dim val As Integer = TrackBar1.Value
Chart1.ChartAreas(0).AxisX.Maximum = Date.Today.AddDays(val).ToOADate()
End Sub
End Class
Or if you don't know the min and max dates already, you can set the axis maximum relative to the position of the TrackBar:
Private Sub TrackBar1_Scroll(sender As Object, e As EventArgs) Handles TrackBar1.Scroll
' Get min and max dates
Dim maxDate As Date = Date.FromOADate(Chart1.Series("s").Points.FindMaxByValue("X").XValue)
Dim minDate As Date = Date.FromOADate(Chart1.Series("s").Points.FindMinByValue("X").XValue)
' Get total days between dates
Dim totalDays = maxDate.Subtract(minDate).Days
' Get the bar position as a percent of 100
Dim barPct As Double = TrackBar1.Value / TrackBar1.Maximum
' Find the maximum day that should be displayed on the plot
Dim maxAxisDay As Integer = barPct * totalDays
' Get the date of the maximum day
Dim maxAxisDate = minDate.AddDays(maxAxisDay)
' Set maximum. Convert the date to a double using .ToOADate()
Chart1.ChartAreas(0).AxisX.Maximum = maxAxisDate.ToOADate()
End Sub
Edit:
Assuming that the trackbar maximum is set to the total number of days represented by the dataset, it's a bit easier:
Private Sub TrackBar1_Scroll_1(sender As Object, e As EventArgs) Handles TrackBar1.Scroll
' Get the first date
Dim minDate As Date = Date.FromOADate(Chart1.Series("s").Points.FindMinByValue("X").XValue)
' Assuming that the trackbar has the total number of days represented, the maximum date to display is the first date plus the
' days represented by the trackbar
Dim maxDisplayDate As Date = minDate.AddDays(TrackBar1.Value)
' Set the max axis
Chart1.ChartAreas(0).AxisX.Maximum = maxDisplayDate.ToOADate()
End Sub