Cast to TObject - sql

Question

I am struggling to get the ItemIndex of my a Item in my TComoBox...
Usually that doesn't seem to be a hard thing to do for me... but somehow when i try to cast my String(which I got from a SQL select) to a TObject. That doesn't seem to work. I tried to debug my code with writing the String manually into the Object like so:
TObject('U');
That somehow does work, i just cant explain that...
The way i fill the ComoBox:
for i := Low(_VerkaufTypenBez) to High(_VerkaufTypenBez) do
begin
CBBelegart.AddItem(VerkaufTypenBez(i), Tobject(VerkaufTypenShort[i]));
end;
The way i tried to set the Index:
CB.ItemIndex := CB.Items.IndexOfObject(TObject(SetIndexWithSQL('select top 1 * from KOMSAconfig_Allgemein', 'Belegart'))); //index = -1
helper := 'U';
CB.ItemIndex := CB.Items.IndexOfObject(TObject(helper)); //index = -1
CB.ItemIndex := CB.Items.IndexOfObject(TObject('U')); //index = 1
Any suggestions?

Answer 1

This is what happens when you try to use a visual control as if it were a general purpose container. A visual control is used purely for display and user interaction. Don't try to bend it to do more than that.
In your scenario it is pointless to attempt to add a second string into the combo box. Stop doing that. Change your loop that populates to be like so:
for i := Low(_VerkaufTypenBez) to High(_VerkaufTypenBez) do
begin
CBBelegart.Items.Add(VerkaufTypenBez(i));
end;
The other string is held in an array like structure and seemingly can be accessed like this: VerkaufTypenShort[i]. So, if you want to lookup the index of a particular value, that can be done like so:
function GetIndexFromShortString(const Value: string): Integer;
begin
for Result := Low(_VerkaufTypenBez) to High(_VerkaufTypenBez) do
if VerkaufTypenShort[Result]=Value then
exit;
Result := -1;
end;
Notice that this function is completely independent of the visual control. You should strive to use visual controls for the bare minimum, and write your business logic without reference to any visual controls.

Answer 2

Your problem here seems to be that you get two strings from your query, where one is used as display text and the other is needed for internal lookups (coming from a different query).
I see two ways to solve this:
change your second query, so it returns the string, that is used in the combobox
have a lookup in your form that connects both strings
For the second you could use a TDictionary. My approach here assumes that filling the combobox is done only in one loop and there aren't strings added or removed dynamically.
Add the Dictionary to your form:
TForm1 = class(TForm)
...
private
FLookUp: TDictionary<string, Integer>;
In the FormCreate and FormDestroy events create and destroy your Dictionary.
FLookUp := TDictionary<string, Integer>.Create;
FLookUp.Free;
In the loop you use to fill the Combobox, store the Indices and connect them to your lookup-strings (I just copied your loop, assuming that it works as is).
procedure TForm1.FillCombo;
var
Index, I: Integer;
begin
FLookUp.Clear;
for i := Low(_VerkaufTypenBez) to High(_VerkaufTypenBez) do
begin
Index := CBBelegart.Items.Add(VerkaufTypenBez(i));
FLookUp.Add(VerkaufTypenShort[i], Index);
end;
end;
Now you can look for the correct Index using that Dictionary
function TForm1.GetIndexOfString(const Value: string): Integer;
begin
if not FLookUp.TryGetValue(Value, Result) then
Result := -1;
end;
Use it like
CB.ItemIndex := GetIndexOfString(SetIndexWithSQL(...));