Excel VBA - search, offset, replace - vba

Question

I have a settings sheet with unique identifiers in column D and replacement values in column F. I need to:
loop through all serial numbers in sheet settingscolumn D
find the row with the same serial in sheet test column A
get the replacement value from settings column F
replace the data in column B on the test sheet, in the same row as the previously searched serial
sounds simple enough but I am getting a type mismatch error when defining the for and to statement with the code below.
Sub Replace_List()
Dim rList As Range, cell As Range, n As Long
Application.ScreenUpdating = False
With ThisWorkbook.Sheets("Settings")
Set rList = .Range("D4", .Range("D" & Rows.Count).End(xlUp))
End With
For Each cell In rList
For n = cell.Value To cell.Offset(0, 2).Value Step 1
ThisWorkbook.Sheets("test").Columns("B:B").Replace What:=n, _
Replacement:=cell.Offset(0, 2).Value, _
LookAt:=xlWhole
Next n
Next cell
Application.ScreenUpdating = True
MsgBox "Replaced all items from the list.", vbInformation, "Replacements Complete"
End Sub
Any pointers on what I am doing wrong here are appreciated.
Thanks,
A2k
EDIT
Screenshots below:
Settings - I am looking up the survey ID and want to replace the original date with the correct one

Answer 1

I believe you want to use Find to find each occurrence, and then replace the value using an Offset of the found location:
Sub Replace_List()
Dim rList As Range, cel As Range, n As Long
Dim fnd As Range
Dim fndFirst As String
Application.ScreenUpdating = False
With ThisWorkbook.Sheets("Settings")
Set rList = .Range("D4", .Range("D" & .Rows.Count).End(xlUp))
End With
For Each cel In rList
Set fnd = ThisWorkbook.Worksheets("test").Columns("A:A").Find(What:=cel.Value, LookAt:=xlWhole)
If Not fnd Is Nothing Then
fndFirst = fnd.Address
Do
fnd.Offset(0, 1).Value = cel.Offset(0, 2).Value
Set fnd = ThisWorkbook.Worksheets("test").Columns("A:A").FindNext(After:=fnd)
Loop While fnd.Address <> fndFirst
End If
Next
Application.ScreenUpdating = True
MsgBox "Replaced all items from the list.", vbInformation, "Replacements Complete"
End Sub