VBA - looping multiple record sets - vba

Question

I think I have a fairly simple question to answer. The below code works perfectly as is, with an end result of populating 2 of my userform's combo boxes with field data from an Access data base. I still have several more combo boxes to fill with access data. I am looking for a way to loop through multiple SQL statements in a single record set rather than needing to create a new record set for each SQL query. As always, much appreciated.
Const conStrAccess As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data
Source=C:\Users\Andy\Desktop\Database\IATC.accdb;Persist Security
Info=False;"
Const providerSQL As String = "SELECT DISTINCT [Provider Name] FROM
tblProvider ORDER BY [Provider Name];"
Const employeeSQL As String = "SELECT DISTINCT [Employee Name] FROM
tblEmployee ORDER BY [Employee Name];"
Dim aConn As ADODB.Connection
Dim providerData As ADODB.Recordset
Dim employeeData As ADODB.Recordset
Set aConn = New ADODB.Connection
Set providerData = New ADODB.Recordset
Set employeeData = New ADODB.Recordset
aConn.ConnectionString = conStrAccess
aConn.Open
aConn.ConnectionString = conStrAccess
aConn.Open
providerData.Open providerSQL, aConn, adOpenStatic, adLockReadOnly
providerData.MoveFirst
With Me.cbxProvider
.Clear
Do
.AddItem providerData![Provider Name]
providerData.MoveNext
Loop Until providerData.EOF
End With
employeeData.Open employeeSQL, aConn, adOpenStatic, adLockReadOnly
employeeData.MoveFirst
With Me.cbxEmployee
.Clear
Do
.AddItem employeeData![Employee Name]
employeeData.MoveNext
Loop Until employeeData.EOF
End With

Answer 1

Consider not using any recordsets at all as MS Access form comboboxes and listboxes can use tables and queries as rowsources:
Dim var As Variant, varList As Variant
varList = Array("Provider", "Employee")
For Each var in varList
sql = "SELECT DISTINCT [" & var & " Name] " _
& " FROM tbl" & var & " ORDER BY [" & var & " Name];"
With Me.Form.Controls("cbx" & var)
.RowSourceType = "Table/Query"
.RowSource = sql
.Requery
End With
Next var

Answer 2

In programming a useful rule of thumb is "don't repeat yourself" ("DRY"). If you find you're writing the same code over and over with consistent variations, then you should refactor that code out into a separate method, with some parameters to manage the variations.
Untested:
Sub Main()
Const conStrAccess As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data " & _
"Source=C:\Users\Andy\Desktop\Database\IATC.accdb;Persist Security Info=False;"
Const providerSQL As String = "SELECT DISTINCT [Provider Name] FROM tblProvider ORDER BY [Provider Name]"
Const employeeSQL As String = "SELECT DISTINCT [Employee Name] FROM tblEmployee ORDER BY [Employee Name]"
Dim aConn As New ADODB.Connection
aConn.Open conStrAccess
FillListBox aConn, providerSQL, Me.cbxProvider
FillListBox aConn, employeeSQL, Me.cbxEmployee
'...more lists...
aConn.Close
End Sub
'Fill a combobox from a single-field SQL query
Sub FillComboBox(con As ADODB.Connection, SQL As String, cb)
Dim rs As New ADODB.Recordset
rs.Open SQL, con, adOpenStatic, adLockReadOnly
With cb
.Clear
Do While Not rs.EOF
.AddItem rs.Fields(0).Value
rs.MoveNext
Loop
End With
rs.Close
End Sub